| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 1 | SUMMARY = "A UPnP AV media server and renderer" |
| 2 | DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \ |
| 3 | allow you to easily share audio, video and pictures to other devices. \ |
| 4 | Additionally, media player software may use Rygel to become a MediaRenderer \ |
| 5 | that may be controlled remotely by a UPnP or DLNA Controller." |
| 6 | HOMEPAGE = "http://live.gnome.org/Rygel" |
| 7 | |
| 8 | LICENSE = "LGPL-2.1" |
| 9 | LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c" |
| 10 | |
| 11 | DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base libgee libsoup-2.4 libmediaart-2.0 libunistring sqlite3 intltool-native" |
| 12 | RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback shared-mime-info" |
| 13 | RRECOMMENDS_${PN} = "rygel-plugin-media-export" |
| 14 | |
| 15 | inherit gnomebase vala gobject-introspection gettext systemd |
| 16 | |
| 17 | SRC_URI[archive.md5sum] = "7f95401903a3f855b464d5152b9d4c07" |
| 18 | SRC_URI[archive.sha256sum] = "08c21a577f7bdad26446a75ffa32778b26842c3b1188165f0b19818559747d00" |
| 19 | |
| 20 | EXTRA_OECONF = "--disable-tracker-plugin --with-media-engine=gstreamer" |
| 21 | |
| 22 | PACKAGECONFIG ?= "external mpris ruih media-export gst-launch" |
| 23 | |
| 24 | PACKAGECONFIG_append = "${@bb.utils.contains("DISTRO_FEATURES", "x11", " gtk+3", "", d)}" |
| 25 | |
| 26 | PACKAGECONFIG[external] = "--enable-external-plugin,--disable-external-plugin" |
| 27 | PACKAGECONFIG[mpris] = "--enable-mpris-plugin,--disable-mpris-plugin" |
| 28 | PACKAGECONFIG[ruih] = "--enable-ruih-plugin,--disable-ruih-plugin" |
| 29 | PACKAGECONFIG[media-export] = "--enable-media-export-plugin,--disable-media-export-plugin" |
| 30 | PACKAGECONFIG[gst-launch] = "--enable-gst-launch-plugin,--disable-gst-launch-plugin" |
| 31 | PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3" |
| 32 | PACKAGECONFIG[lms] = "--enable-lms-plugin,--disable-lms-plugin" |
| 33 | |
| 34 | LIBV = "2.6" |
| 35 | |
| 36 | do_install_append() { |
| 37 | # Remove .la files for loadable modules |
| 38 | rm -f ${D}/${libdir}/rygel-${LIBV}/engines/*.la |
| 39 | rm -f ${D}/${libdir}/rygel-${LIBV}/plugins/*.la |
| 40 | if [ -e ${D}${nonarch_libdir}/systemd/user/rygel.service ]; then |
| 41 | mkdir -p ${D}${systemd_unitdir}/system |
| 42 | mv ${D}${nonarch_libdir}/systemd/user/rygel.service ${D}${systemd_unitdir}/system |
| 43 | rmdir --ignore-fail-on-non-empty ${D}${nonarch_libdir}/systemd/user \ |
| 44 | ${D}${nonarch_libdir}/systemd \ |
| 45 | ${D}${nonarch_libdir} |
| 46 | fi |
| 47 | } |
| 48 | |
| 49 | FILES_${PN} += "${libdir}/rygel-${LIBV}/engines ${datadir}/dbus-1 ${datadir}/icons" |
| 50 | FILES_${PN}-dbg += "${libdir}/rygel-${LIBV}/engines/.debug ${libdir}/rygel-${LIBV}/plugins/.debug" |
| 51 | |
| 52 | PACKAGES += "${PN}-meta" |
| 53 | ALLOW_EMPTY_${PN}-meta = "1" |
| 54 | |
| 55 | PACKAGES_DYNAMIC = "${PN}-plugin-*" |
| 56 | |
| 57 | SYSTEMD_SERVICE_${PN} = "rygel.service" |
| 58 | |
| 59 | python populate_packages_prepend () { |
| 60 | rygel_libdir = d.expand('${libdir}/rygel-${LIBV}') |
| 61 | postinst = d.getVar('plugin_postinst') |
| 62 | pkgs = [] |
| 63 | |
| 64 | pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), 'librygel-(.*)\.so$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}')) |
| 65 | pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), '(.*)\.plugin$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}')) |
| 66 | |
| 67 | metapkg = d.getVar('PN') + '-meta' |
| 68 | d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs)) |
| 69 | } |