| Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 1 | SUMMARY = "Tool Command Language" |
| 2 | HOMEPAGE = "http://tcl.sourceforge.net" |
| 3 | SECTION = "devel/tcltk" |
| 4 | |
| 5 | # http://www.tcl.tk/software/tcltk/license.html |
| 6 | LICENSE = "tcl & BSD-3-Clause" |
| 7 | LIC_FILES_CHKSUM = "file://../license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 8 | file://../compat/license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 9 | file://../library/license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 10 | file://../macosx/license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 11 | file://../tests/license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 12 | file://../win/license.terms;md5=058f6229798281bbcac4239c788cfa38 \ |
| 13 | " |
| 14 | |
| 15 | DEPENDS = "tcl-native zlib" |
| 16 | |
| 17 | BASE_SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/${BPN}${PV}-src.tar.gz \ |
| 18 | file://tcl-add-soname.patch" |
| 19 | SRC_URI = "${BASE_SRC_URI} \ |
| 20 | file://fix_non_native_build_issue.patch \ |
| 21 | file://fix_issue_with_old_distro_glibc.patch \ |
| 22 | file://no_packages.patch \ |
| 23 | file://tcl-remove-hardcoded-install-path.patch \ |
| 24 | file://alter-includedir.patch \ |
| 25 | file://run-ptest \ |
| 26 | " |
| 27 | SRC_URI[md5sum] = "d7cbb91f1ded1919370a30edd1534304" |
| 28 | SRC_URI[sha256sum] = "9e6ed94c981c1d0c5f5fefb8112d06c6bf4d050a7327e95e71d417c416519c8d" |
| 29 | |
| 30 | SRC_URI_class-native = "${BASE_SRC_URI}" |
| 31 | |
| 32 | S = "${WORKDIR}/${BPN}${PV}/unix" |
| 33 | |
| 34 | VER = "${PV}" |
| 35 | |
| 36 | inherit autotools ptest binconfig |
| 37 | |
| 38 | DEPENDS_class-native = "zlib-native" |
| 39 | |
| 40 | EXTRA_OECONF = "--enable-threads --disable-rpath --libdir=${libdir}" |
| 41 | |
| 42 | do_configure() { |
| 43 | cd ${S} |
| 44 | gnu-configize |
| 45 | cd ${B} |
| 46 | oe_runconf |
| 47 | } |
| 48 | |
| 49 | do_compile_prepend() { |
| 50 | echo > ${S}/../compat/fixstrtod.c |
| 51 | } |
| 52 | |
| 53 | do_install() { |
| 54 | autotools_do_install install-private-headers |
| 55 | ln -sf ./tclsh${VER} ${D}${bindir}/tclsh |
| 56 | ln -sf tclsh8.6 ${D}${bindir}/tclsh${VER} |
| 57 | sed -i "s+-L${B}+-L${STAGING_LIBDIR}+g" tclConfig.sh |
| 58 | sed -i "s+${WORKDIR}+${STAGING_INCDIR}+g" tclConfig.sh |
| 59 | sed -i "s,-L${libdir},-L=${libdir},g" tclConfig.sh |
| 60 | sed -i "s,-I${includedir},-I=${includedir},g" tclConfig.sh |
| 61 | install -d ${D}${bindir_crossscripts} |
| 62 | install -m 0755 tclConfig.sh ${D}${bindir_crossscripts} |
| 63 | install -m 0755 tclConfig.sh ${D}${libdir} |
| 64 | cd .. |
| 65 | for dir in compat generic unix; do |
| 66 | install -d ${D}${includedir}/${BPN}${VER}/$dir |
| 67 | install -m 0644 ${S}/../$dir/*.h ${D}${includedir}/${BPN}${VER}/$dir/ |
| 68 | done |
| 69 | } |
| 70 | |
| 71 | SYSROOT_PREPROCESS_FUNCS += "tcl_sysroot_preprocess" |
| 72 | tcl_sysroot_preprocess () { |
| 73 | sysroot_stage_dir ${D}${bindir_crossscripts} ${SYSROOT_DESTDIR}${bindir_crossscripts} |
| 74 | } |
| 75 | |
| 76 | PACKAGES =+ "tcl-lib" |
| 77 | FILES_tcl-lib = "${libdir}/libtcl8.6.so.*" |
| 78 | FILES_${PN} += "${libdir}/tcl${VER} ${libdir}/tcl8.6 ${libdir}/tcl8" |
| 79 | FILES_${PN}-dev += "${libdir}/tclConfig.sh ${libdir}/tclooConfig.sh" |
| 80 | |
| 81 | # isn't getting picked up by shlibs code |
| 82 | RDEPENDS_${PN} += "tcl-lib" |
| 83 | RDEPENDS_${PN}_class-native = "" |
| 84 | RDEPENDS_${PN}-ptest += "libgcc" |
| 85 | |
| 86 | BBCLASSEXTEND = "native" |
| 87 | |
| 88 | do_compile_ptest() { |
| 89 | oe_runmake tcltest |
| 90 | } |
| 91 | |
| 92 | do_install_ptest() { |
| 93 | cp ${B}/tcltest ${D}${PTEST_PATH} |
| 94 | cp -r ${S}/../library ${D}${PTEST_PATH} |
| 95 | cp -r ${S}/../tests ${D}${PTEST_PATH} |
| 96 | } |
| 97 | |
| 98 | # Fix some paths that might be used by Tcl extensions |
| 99 | BINCONFIG_GLOB = "*Config.sh" |
| 100 | |
| 101 | # Fix the path in sstate |
| 102 | SSTATE_SCAN_FILES += "*Config.sh" |