Patrick Williams | c124f4f | 2015-09-15 14:41:29 -0500 | [diff] [blame] | 1 | SUMMARY = "C library for embedded systems" |
| 2 | DESCRIPTION = "The name uClibc is an abbreviation for 'the \ |
| 3 | microcontroller C library'. For simplicity, uClibc is pronounced \ |
| 4 | 'yew-see-lib-see'. The goal of uClibc is to provide as much \ |
| 5 | functionality as possible in a small amount of space, and it is intended \ |
| 6 | primarily for embedded use. It is also highly configurable in supported \ |
| 7 | features, at the cost of ABI differences for different configurations. \ |
| 8 | uClibc has been designed from the ground up to be a C library for \ |
| 9 | embedded Linux. It is NOT compatible with binaries linked against glibc." |
| 10 | |
| 11 | LICENSE = "LGPLv2.1+" |
| 12 | SECTION = "libs" |
| 13 | LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=a6f89e2100d9b6cdffcea4f398e37343 \ |
| 14 | file://COPYING.LIB.boilerplate;md5=aaddeadcddeb918297e0e4afc52ce46f \ |
| 15 | file://${S}/test/regex/testregex.c;beginline=1;endline=31;md5=234efb227d0a40677f895e4a1e26e960" |
| 16 | PR = "r9" |
| 17 | |
| 18 | require uclibc-config.inc |
| 19 | |
| 20 | PATH_prepend = "${STAGING_BINDIR_TOOLCHAIN}.${STAGINGCC}:" |
| 21 | TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TCBOOTSTRAP}" |
| 22 | |
| 23 | # siteconfig.bbclass runs configure which needs a working compiler |
| 24 | # For the compiler to work we need a working libc yet libc isn't |
| 25 | # in the sysroots directory at this point. This means the libc.so |
| 26 | # linker script won't work as the --sysroot setting isn't correct. |
| 27 | # Here we create a hacked up libc linker script and pass in the right |
| 28 | # flags to let configure work. Ugly. |
| 29 | EXTRASITECONFIG = "CFLAGS='${CFLAGS} -Wl,-L${WORKDIR}/site_config_libc -L${WORKDIR}/site_config_libc -L${SYSROOT_DESTDIR}${libdir} -L${SYSROOT_DESTDIR}${base_libdir} -Wl,-L${SYSROOT_DESTDIR}${libdir} -Wl,-L${SYSROOT_DESTDIR}${base_libdir}'" |
| 30 | siteconfig_do_siteconfig_gencache_prepend = " \ |
| 31 | mkdir -p ${WORKDIR}/site_config_libc; \ |
| 32 | cp ${SYSROOT_DESTDIR}${libdir}/libc.so ${WORKDIR}/site_config_libc; \ |
| 33 | sed -i -e 's# ${base_libdir}# ${SYSROOT_DESTDIR}${base_libdir}#g' -e 's# ${libdir}# ${SYSROOT_DESTDIR}${libdir}#g' ${WORKDIR}/site_config_libc/libc.so; \ |
| 34 | " |
| 35 | |
| 36 | # For now, we will skip building of a gcc package if it is a uclibc one |
| 37 | # and our build is not a uclibc one, and we skip a glibc one if our build |
| 38 | # is a uclibc build. |
| 39 | COMPATIBLE_HOST = ".*-uclibc.*" |
| 40 | |
| 41 | INHIBIT_DEFAULT_DEPS = "1" |
| 42 | |
| 43 | # do_stage barfs on a CC with whitespace, therefore put the 'HOST_CC_ARCH' in |
| 44 | # the CFLAGS (when building the utils). |
| 45 | OEMAKE_NO_CC = "'STRIPTOOL=true' 'LD=${LD}'" |
| 46 | EXTRA_OEMAKE = "${OEMAKE_NO_CC} \ |
| 47 | 'HOSTCC=${BUILD_CC}' \ |
| 48 | 'HOST_CFLAGS=${BUILD_CFLAGS}' \ |
| 49 | 'CC=${CC}' \ |
| 50 | ARCH=${UCLIBC_ARCH}" |
| 51 | |
| 52 | EXTRA_OEMAKE_task_do_package = "${OEMAKE_NO_CC}" |
| 53 | |
| 54 | # enable verbose output: |
| 55 | export V="2" |
| 56 | |
| 57 | # -O<n> -fno-omit-frame-pointer ends up with GCC ICE on thumb as reported |
| 58 | # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=44860 |
| 59 | # |
| 60 | CFLAGS_arm := "${@oe_filter_out('-fno-omit-frame-pointer', '${CFLAGS}', d)}" |
| 61 | UCLIBC_EXTRA_CFLAGS := "${@oe_filter_out('(-I\S+|-i\S+)', '${CFLAGS}', d)}" |
| 62 | |
| 63 | do_compile_prepend () { |
| 64 | unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS |
| 65 | oe_runmake pregen |
| 66 | } |
| 67 | |
| 68 | configmangle = '/^KERNEL_HEADERS/d; \ |
| 69 | /^RUNTIME_PREFIX/d; \ |
| 70 | /^DEVEL_PREFIX/d; \ |
| 71 | /^SHARED_LIB_LOADER_PREFIX/d; \ |
| 72 | /^UCLIBC_EXTRA_CFLAGS/d; \ |
| 73 | s,.*UCLIBC_HAS_WCHAR.*,UCLIBC_HAS_WCHAR=y,g; \ |
| 74 | ${@["","s,.*COMPILE_IN_THUMB_MODE.*,COMPILE_IN_THUMB_MODE=y,;"][d.getVar("ARM_INSTRUCTION_SET", True) != "arm"]} \ |
| 75 | ${@["","s,.*UCLIBC_HAS_LOCALE.*,UCLIBC_HAS_LOCALE=y,;"][d.getVar("USE_NLS", True) == "yes"]} \ |
| 76 | ${@["","s,.*LDSO_GNU_HASH_SUPPORT.*,# LDSO_GNU_HASH_SUPPORT is not set,;"][d.getVar("TARGET_ARCH", True) in ['mips', 'mipsel', 'mips64', 'mips64el', 'avr32']]} \ |
| 77 | /^CROSS/d; \ |
| 78 | /^TARGET_ARCH=/d; \ |
| 79 | /^TARGET_/s,^\([^=]*\).*,# \1 is not set,g; \ |
| 80 | s,^DOSTRIP.*,# DOSTRIP is not set,g; \ |
| 81 | /_[EO]*ABI/d; \ |
| 82 | /HAS_FPU/d; \ |
| 83 | ${@["","s,.*MULTILIB_DIR.*,MULTILIB_DIR=\"${baselib}\",;"][d.getVar("baselib", True) != "lib"]} \ |
| 84 | ' |
| 85 | OE_FEATURES := "${@features_to_uclibc_conf(d)}" |
| 86 | OE_DEL := "${@features_to_uclibc_del(d)}" |
| 87 | python () { |
| 88 | if "${OE_DEL}": |
| 89 | d.setVar('configmangle_append', "${OE_DEL}" + "\n") |
| 90 | |
| 91 | # by default uclibc uses mips1 ISA for o32 ABI |
| 92 | # if we use TARGET_CC_ARCH="-march=mips32" we end up |
| 93 | # with conflicting march options to gcc. Here we |
| 94 | # ask for MIPS32 ISA to match the chosen arch |
| 95 | tune = d.getVar("DEFAULTTUNE", True) |
| 96 | if tune.startswith('mips32'): |
| 97 | import re |
| 98 | tune = re.sub('(el)*(-nf)*', '', tune) |
| 99 | d.setVar('configmangle_append', |
| 100 | "/^### MIPS32_CHECK$/a\\\nCONFIG_MIPS_ISA_%s=y\n\n" % (tune.upper())) |
| 101 | if "${OE_FEATURES}": |
| 102 | d.setVar('configmangle_append', |
| 103 | "/^### DISTRO FEATURES$/a\\\n%s\n\n" % |
| 104 | ("\\n".join((d.expand("${OE_FEATURES}").split("\n"))))) |
| 105 | d.setVar('configmangle_append', |
| 106 | "/^### CROSS$/a\\\n%s\n" % |
| 107 | ("\\n".join(["CROSS_COMPILER_PREFIX=\"${TARGET_PREFIX}\"", |
| 108 | "UCLIBC_EXTRA_CFLAGS=\"${UCLIBC_EXTRA_CFLAGS}\"", |
| 109 | "KERNEL_HEADERS=\"${STAGING_INCDIR}\"", |
| 110 | "RUNTIME_PREFIX=\"/\"", |
| 111 | "DEVEL_PREFIX=\"/${prefix}\"", |
| 112 | "SHARED_LIB_LOADER_PREFIX=\"/lib\"", |
| 113 | ]) |
| 114 | )) |
| 115 | d.setVar('configmangle_append', |
| 116 | "/^### TGT$/a\\\nTARGET_ARCH=\"%s\"\\nTARGET_%s=y\n" % |
| 117 | ("${UCLIBC_ARCH}", "${UCLIBC_ARCH}")) |
| 118 | d.setVar('configmangle_append', |
| 119 | "/^### FPU$/a\\\n%s\n\n" % (["UCLIBC_HAS_FPU=y","# UCLIBC_HAS_FPU is not set"][d.getVar('TARGET_FPU', True) in [ 'soft' ]])) |
| 120 | if "${UCLIBC_ENDIAN}": |
| 121 | d.setVar('configmangle_append', |
| 122 | "/^### ABI$/a\\\nARCH_WANTS_%s_ENDIAN=y\n\n" % ("${UCLIBC_ENDIAN}")) |
| 123 | if "${UCLIBC_ABI}": |
| 124 | d.setVar('configmangle_append', |
| 125 | "/^### ABI$/a\\\nCONFIG_%s=y\n\n" % ("${UCLIBC_ABI}")) |
| 126 | } |
| 127 | |
| 128 | python do_patch_append() { |
| 129 | import subprocess |
| 130 | subprocess.call("ln -sf ${STAGING_INCDIR}/linux ${S}/include/linux", shell=True) |
| 131 | subprocess.call("ln -sf ${STAGING_INCDIR}/asm ${S}/include/asm", shell=True) |
| 132 | } |
| 133 | |
| 134 | do_configure() { |
| 135 | rm -f ${S}/.config |
| 136 | |
| 137 | # OpenEmbedded splits the uClibc.config in two parts: |
| 138 | # uClibc.machine, uClibc.distro |
| 139 | echo "### uClibc.machine ###" >${S}/merged.config |
| 140 | cat ${WORKDIR}/uClibc.machine >>${S}/merged.config |
| 141 | echo "### uClibc.distro ###" >>${S}/merged.config |
| 142 | cat ${WORKDIR}/uClibc.distro >>${S}/merged.config |
| 143 | echo "### CROSS" >>${S}/merged.config |
| 144 | echo "### TGT" >>${S}/merged.config |
| 145 | echo "### MMU" >>${S}/merged.config |
| 146 | echo "### FPU" >>${S}/merged.config |
| 147 | echo "### ABI" >>${S}/merged.config |
| 148 | echo "### DISTRO FEATURES" >>${S}/merged.config |
| 149 | echo "### MIPS32_CHECK" >>${S}/merged.config |
| 150 | |
| 151 | # Mangle the resulting .config depending on OE variables |
| 152 | sed -i -e '${configmangle}' ${S}/merged.config |
| 153 | cp ${S}/merged.config .config |
| 154 | merge_config.sh -r -n -m .config ${@" ".join(find_cfgs(d))} |
| 155 | cml1_do_configure |
| 156 | |
| 157 | } |
| 158 | |
| 159 | do_install() { |
| 160 | oe_runmake PREFIX=${D} install |
| 161 | rm -rf ${D}${includedir}/iconv.h |
| 162 | } |
| 163 | |
| 164 | # build ldd, ldconfig and friends but only for full uclibc |
| 165 | do_install_append_pn-uclibc () { |
| 166 | oe_runmake PREFIX=${D} "SSP_ALL_CFLAGS=${TARGET_LINK_HASH_STYLE}" -C utils utils_install |
| 167 | } |
| 168 | |