| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 1 | SUMMARY = "Open Package Manager" |
| 2 | SUMMARY_libopkg = "Open Package Manager library" |
| 3 | SECTION = "base" |
| 4 | HOMEPAGE = "http://code.google.com/p/opkg/" |
| 5 | BUGTRACKER = "http://code.google.com/p/opkg/issues/list" |
| 6 | LICENSE = "GPLv2+" |
| 7 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \ |
| 8 | file://src/opkg.c;beginline=4;endline=18;md5=d6200b0f2b41dee278aa5fad333eecae" |
| 9 | |
| 10 | DEPENDS = "libarchive" |
| 11 | |
| 12 | PE = "1" |
| 13 | |
| 14 | SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \ |
| 15 | file://opkg.conf \ |
| 16 | file://0001-opkg_conf-create-opkg.lock-in-run-instead-of-var-run.patch \ |
| 17 | file://run-ptest \ |
| 18 | " |
| 19 | |
| Andrew Geissler | 706d5aa | 2021-02-12 15:55:30 -0600 | [diff] [blame^] | 20 | SRC_URI[md5sum] = "86ec5eee9362aca0990994a402e077e9" |
| 21 | SRC_URI[sha256sum] = "dda452854bc0cd1334f7ba18a66003d1c12a98600c894111b56919b1ea434718" |
| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 22 | |
| 23 | # This needs to be before ptest inherit, otherwise all ptest files end packaged |
| 24 | # in libopkg package if OPKGLIBDIR == libdir, because default |
| 25 | # PTEST_PATH ?= "${libdir}/${BPN}/ptest" |
| 26 | PACKAGES =+ "libopkg" |
| 27 | |
| 28 | inherit autotools pkgconfig ptest |
| 29 | |
| 30 | target_localstatedir := "${localstatedir}" |
| 31 | OPKGLIBDIR ??= "${target_localstatedir}/lib" |
| 32 | |
| 33 | PACKAGECONFIG ??= "libsolv" |
| 34 | |
| 35 | PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,\ |
| 36 | gnupg gpgme libgpg-error,\ |
| 37 | ${@ "gnupg" if ("native" in d.getVar("PN")) else "gnupg-gpg"}\ |
| 38 | " |
| 39 | PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl" |
| 40 | PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl" |
| 41 | PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl" |
| 42 | PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256" |
| 43 | PACKAGECONFIG[libsolv] = "--with-libsolv,--without-libsolv,libsolv" |
| 44 | |
| 45 | EXTRA_OECONF += " --disable-pathfinder" |
| 46 | EXTRA_OECONF_class-native = "--localstatedir=/${@os.path.relpath('${localstatedir}', '${STAGING_DIR_NATIVE}')} --sysconfdir=/${@os.path.relpath('${sysconfdir}', '${STAGING_DIR_NATIVE}')}" |
| 47 | |
| 48 | do_install_append () { |
| 49 | install -d ${D}${sysconfdir}/opkg |
| 50 | install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf |
| 51 | echo "option lists_dir ${OPKGLIBDIR}/opkg/lists" >>${D}${sysconfdir}/opkg/opkg.conf |
| 52 | |
| 53 | # We need to create the lock directory |
| 54 | install -d ${D}${OPKGLIBDIR}/opkg |
| 55 | } |
| 56 | |
| 57 | do_install_ptest () { |
| 58 | sed -i -e '/@echo $^/d' ${D}${PTEST_PATH}/tests/Makefile |
| 59 | sed -i -e '/@PYTHONPATH=. $(PYTHON) $^/a\\t@if [ "$$?" != "0" ];then echo "FAIL:"$^;else echo "PASS:"$^;fi' ${D}${PTEST_PATH}/tests/Makefile |
| 60 | } |
| 61 | |
| 62 | RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config libarchive" |
| 63 | RDEPENDS_${PN}_class-native = "" |
| 64 | RDEPENDS_${PN}_class-nativesdk = "" |
| 65 | RDEPENDS_${PN}-ptest += "make binutils python3-core python3-compression" |
| 66 | RREPLACES_${PN} = "opkg-nogpg opkg-collateral" |
| 67 | RCONFLICTS_${PN} = "opkg-collateral" |
| 68 | RPROVIDES_${PN} = "opkg-collateral" |
| 69 | |
| 70 | FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/" |
| 71 | |
| 72 | BBCLASSEXTEND = "native nativesdk" |
| 73 | |
| 74 | CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf" |