Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 1 | SUMMARY = "NetworkManager" |
| 2 | HOMEPAGE = "https://wiki.gnome.org/Projects/NetworkManager" |
| 3 | SECTION = "net/misc" |
| 4 | |
| 5 | LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \ |
| 7 | file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \ |
| 8 | " |
| 9 | |
| 10 | DEPENDS = " \ |
| 11 | coreutils-native \ |
| 12 | intltool-native \ |
| 13 | libxslt-native \ |
| 14 | libnl \ |
| 15 | udev \ |
| 16 | util-linux \ |
| 17 | libndp \ |
| 18 | libnewt \ |
| 19 | curl \ |
| 20 | dbus \ |
| 21 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 22 | DEPENDS:append:class-target = " bash-completion" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 23 | |
| 24 | GNOMEBASEBUILDCLASS = "meson" |
| 25 | inherit gnomebase gettext update-rc.d systemd gobject-introspection gtk-doc update-alternatives upstream-version-is-even |
| 26 | |
| 27 | SRC_URI = " \ |
| 28 | ${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \ |
| 29 | file://${BPN}.initd \ |
| 30 | file://enable-dhcpcd.conf \ |
| 31 | file://enable-iwd.conf \ |
| 32 | file://0001-do-not-ask-host-for-ifcfg-defaults.patch \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 33 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 34 | SRC_URI[sha256sum] = "82a4cf07ddfeb0816787b67c0f5058ae6c50d6259c0b0541a24e35156062b2ef" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 35 | |
| 36 | S = "${WORKDIR}/NetworkManager-${PV}" |
| 37 | |
| 38 | # ['auto', 'symlink', 'file', 'netconfig', 'resolvconf'] |
| 39 | NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT ??= "auto" |
| 40 | |
| 41 | # ['dhcpcanon', 'dhclient', 'dhcpcd', 'internal', 'nettools'] |
| 42 | NETWORKMANAGER_DHCP_DEFAULT ??= "internal" |
| 43 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 44 | # The default gets detected based on whether /usr/sbin/nft or /usr/sbin/iptables is installed, with nftables preferred. |
| 45 | # ['', 'iptables', 'nftables'] |
| 46 | NETWORKMANAGER_FIREWALL_DEFAULT ??= "nftables" |
| 47 | |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 48 | EXTRA_OEMESON = "\ |
| 49 | -Difcfg_rh=false \ |
| 50 | -Dtests=yes \ |
| 51 | -Dnmtui=true \ |
| 52 | -Dudev_dir=${nonarch_base_libdir}/udev \ |
| 53 | -Dlibpsl=false \ |
| 54 | -Dqt=false \ |
| 55 | -Dconfig_dns_rc_manager_default=${NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT} \ |
| 56 | -Dconfig_dhcp_default=${NETWORKMANAGER_DHCP_DEFAULT} \ |
| 57 | -Ddhcpcanon=false \ |
| 58 | " |
| 59 | |
| 60 | # stolen from https://github.com/void-linux/void-packages/blob/master/srcpkgs/NetworkManager/template |
| 61 | # avoids: |
| 62 | # | ../NetworkManager-1.16.0/libnm-core/nm-json.c:106:50: error: 'RTLD_DEEPBIND' undeclared (first use in this function); did you mean 'RTLD_DEFAULT'? |
| 63 | CFLAGS:append:libc-musl = " \ |
| 64 | -DRTLD_DEEPBIND=0 \ |
| 65 | " |
| 66 | |
| 67 | do_compile:prepend() { |
| 68 | export GI_TYPELIB_PATH="${B}}/src/libnm-client-impl${GI_TYPELIB_PATH:+:$GI_TYPELIB_PATH}" |
| 69 | } |
| 70 | |
| 71 | PACKAGECONFIG ??= "readline nss ifupdown dnsmasq nmcli vala \ |
| 72 | ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \ |
| 73 | ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \ |
| 74 | ${@bb.utils.filter('DISTRO_FEATURES', 'wifi polkit', d)} \ |
| 75 | ${@bb.utils.contains('DISTRO_FEATURES', 'selinux', 'selinux audit', '', d)} \ |
| 76 | " |
| 77 | |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 78 | inherit ${@bb.utils.contains('PACKAGECONFIG', 'vala', 'vala', '', d)} |
| 79 | |
| 80 | PACKAGECONFIG[systemd] = "\ |
| 81 | -Dsystemdsystemunitdir=${systemd_unitdir}/system -Dsession_tracking=systemd,\ |
| 82 | -Dsystemdsystemunitdir=no -Dsystemd_journal=false -Dsession_tracking=no\ |
| 83 | " |
| 84 | PACKAGECONFIG[polkit] = "-Dpolkit=true,-Dpolkit=false,polkit" |
| 85 | PACKAGECONFIG[bluez5] = "-Dbluez5_dun=true,-Dbluez5_dun=false,bluez5" |
| 86 | # consolekit is not picked by shlibs, so add it to RDEPENDS too |
| 87 | PACKAGECONFIG[consolekit] = "-Dsession_tracking_consolekit=true,-Dsession_tracking_consolekit=false,consolekit,consolekit" |
| 88 | PACKAGECONFIG[modemmanager] = "-Dmodem_manager=true,-Dmodem_manager=false,modemmanager mobile-broadband-provider-info" |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 89 | PACKAGECONFIG[ppp] = "-Dppp=true,-Dppp=false,ppp" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 90 | PACKAGECONFIG[dnsmasq] = "-Ddnsmasq=${bindir}/dnsmasq" |
| 91 | PACKAGECONFIG[nss] = "-Dcrypto=nss,,nss" |
| 92 | PACKAGECONFIG[resolvconf] = "-Dresolvconf=${base_sbindir}/resolvconf,-Dresolvconf=no,,resolvconf" |
| 93 | PACKAGECONFIG[gnutls] = "-Dcrypto=gnutls,,gnutls" |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 94 | PACKAGECONFIG[crypto-null] = "-Dcrypto=null" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 95 | PACKAGECONFIG[wifi] = "-Dwext=true -Dwifi=true,-Dwext=false -Dwifi=false" |
| 96 | PACKAGECONFIG[iwd] = "-Diwd=true,-Diwd=false" |
| 97 | PACKAGECONFIG[ifupdown] = "-Difupdown=true,-Difupdown=false" |
| 98 | PACKAGECONFIG[cloud-setup] = "-Dnm_cloud_setup=true,-Dnm_cloud_setup=false" |
| 99 | PACKAGECONFIG[nmcli] = "-Dnmcli=true,-Dnmcli=false" |
| 100 | PACKAGECONFIG[readline] = "-Dreadline=libreadline,,readline" |
| 101 | PACKAGECONFIG[libedit] = "-Dreadline=libedit,,libedit" |
| 102 | PACKAGECONFIG[ovs] = "-Dovs=true,-Dovs=false,jansson" |
| 103 | PACKAGECONFIG[audit] = "-Dlibaudit=yes,-Dlibaudit=no" |
| 104 | PACKAGECONFIG[selinux] = "-Dselinux=true,-Dselinux=false,libselinux" |
| 105 | PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false" |
| 106 | PACKAGECONFIG[dhcpcd] = "-Ddhcpcd=yes,-Ddhcpcd=no,,dhcpcd" |
| 107 | PACKAGECONFIG[dhclient] = "-Ddhclient=yes,-Ddhclient=no,,dhcp" |
| 108 | PACKAGECONFIG[concheck] = "-Dconcheck=true,-Dconcheck=false" |
| 109 | |
| 110 | |
| 111 | PACKAGES =+ " \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 112 | libnm \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 113 | ${PN}-adsl \ |
| 114 | ${PN}-bluetooth \ |
| 115 | ${PN}-cloud-setup \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 116 | ${PN}-nmcli \ |
| 117 | ${PN}-nmcli-bash-completion \ |
| 118 | ${PN}-nmtui \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 119 | ${PN}-wifi \ |
| 120 | ${PN}-wwan \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 121 | ${PN}-ovs \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 122 | ${PN}-ppp \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 123 | ${PN}-daemon \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 124 | " |
| 125 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 126 | SYSTEMD_PACKAGES = "${PN}-daemon ${PN}-cloud-setup" |
| 127 | INITSCRIPT_PACKAGES = "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 128 | |
| 129 | NETWORKMANAGER_PLUGINDIR = "${libdir}/NetworkManager/${PV}" |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 130 | NETWORKMANAGER_DISPATCHERDIR = "${nonarch_libdir}/NetworkManager/dispatcher.d" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 131 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 132 | |
| 133 | SUMMARY:libnm = "Libraries for adding NetworkManager support to applications" |
| 134 | FILES:libnm = "\ |
| 135 | ${libdir}/libnm.so.* \ |
| 136 | ${libdir}/girepository-1.0/NM-1.0.typelib \ |
| 137 | " |
| 138 | |
| 139 | SUMMARY:${PN}-adsl = "ADSL device plugin for NetworkManager" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 140 | FILES:${PN}-adsl = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-adsl.so" |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 141 | RDEPENDS:${PN}-adsl += "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 142 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 143 | SUMMARY:${PN}-bluetooth = "Bluetooth device plugin for NetworkManager" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 144 | FILES:${PN}-bluetooth = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-bluetooth.so" |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 145 | RDEPENDS:${PN}-bluetooth += "${PN}-daemon ${@bb.utils.contains('PACKAGECONFIG', 'bluez5', '${PN}-wwan bluez5', '', d)}" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 146 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 147 | SUMMARY:${PN}-cloud-setup = "Automatically configure NetworkManager in cloud" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 148 | FILES:${PN}-cloud-setup = " \ |
| 149 | ${libexecdir}/nm-cloud-setup \ |
| 150 | ${systemd_system_unitdir}/nm-cloud-setup.service \ |
| 151 | ${systemd_system_unitdir}/nm-cloud-setup.timer \ |
| 152 | ${libdir}/NetworkManager/dispatcher.d/90-nm-cloud-setup.sh \ |
| 153 | ${libdir}/NetworkManager/dispatcher.d/no-wait.d/90-nm-cloud-setup.sh \ |
| 154 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 155 | RDEPENDS:${PN}-cloud-setup += "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 156 | ALLOW_EMPTY:${PN}-cloud-setup = "1" |
| 157 | SYSTEMD_SERVICE:${PN}-cloud-setup = "${@bb.utils.contains('PACKAGECONFIG', 'cloud-setup', 'nm-cloud-setup.service nm-cloud-setup.timer', '', d)}" |
| 158 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 159 | SUMMARY:${PN}-nmcli = "NetworkManager command line client" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 160 | FILES:${PN}-nmcli = " \ |
| 161 | ${bindir}/nmcli \ |
| 162 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 163 | RDEPENDS:${PN}-nmcli += "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 164 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 165 | SUMMARY:${PN}-nmcli-bash-completion = "NetworkManager command line client bash completion" |
| 166 | FILES:${PN}-nmcli-bash-completion = "${datadir}/bash-completion/completions/nmcli" |
| 167 | RDEPENDS:${PN}-nmcli-bash-completion = "bash-completion" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 168 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 169 | SUMMARY:${PN}-nmtui = "NetworkManager curses-based UI" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 170 | FILES:${PN}-nmtui = " \ |
| 171 | ${bindir}/nmtui \ |
| 172 | ${bindir}/nmtui-edit \ |
| 173 | ${bindir}/nmtui-connect \ |
| 174 | ${bindir}/nmtui-hostname \ |
| 175 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 176 | RDEPENDS:${PN}-nmtui += "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 177 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 178 | SUMMARY:${PN}-wifi = "Wifi plugin for NetworkManager" |
| 179 | FILES:${PN}-wifi = "\ |
| 180 | ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wifi.so \ |
| 181 | ${libdir}/NetworkManager/conf.d/enable-iwd.conf \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 182 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 183 | def get_wifi_deps(d): |
| 184 | packageconfig = (d.getVar('PACKAGECONFIG') or "").split() |
| 185 | if 'wifi' in packageconfig: |
| 186 | if 'iwd' in packageconfig: |
| 187 | return 'iwd' |
| 188 | else: |
| 189 | return 'wpa-supplicant' |
| 190 | else: |
| 191 | return '' |
| 192 | RDEPENDS:${PN}-wifi += "${PN}-daemon ${@get_wifi_deps(d)}" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 193 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 194 | SUMMARY:${PN}-wwan = "Mobile broadband device plugin for NetworkManager" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 195 | FILES:${PN}-wwan = "\ |
| 196 | ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wwan.so \ |
| 197 | ${NETWORKMANAGER_PLUGINDIR}/libnm-wwan.so \ |
| 198 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 199 | RDEPENDS:${PN}-wwan += "${PN}-daemon ${@bb.utils.contains('PACKAGECONFIG','modemmanager','modemmanager','',d)}" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 200 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 201 | SUMMARY:${PN}-ovs = "Open vSwitch device plugin for NetworkManager" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 202 | FILES:${PN}-ovs = "\ |
| 203 | ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-ovs.so \ |
| 204 | ${systemd_system_unitdir}/NetworkManager.service.d/NetworkManager-ovs.conf \ |
| 205 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 206 | RDEPENDS:${PN}-ovs += "${PN}-daemon" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 207 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 208 | SUMMARY:${PN}-ppp = "PPP plugin for NetworkManager" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 209 | FILES:${PN}-ppp = "\ |
| 210 | ${NETWORKMANAGER_PLUGINDIR}/libnm-ppp-plugin.so \ |
| 211 | ${libdir}/pppd/*/nm-pppd-plugin.so \ |
| 212 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 213 | RDEPENDS:${PN}-ppp += "${PN}-daemon ${@bb.utils.contains('PACKAGECONFIG','ppp','ppp','',d)}" |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 214 | |
| 215 | FILES:${PN}-dev += " \ |
| 216 | ${libdir}/pppd/*/*.la \ |
| 217 | ${libdir}/NetworkManager/*.la \ |
| 218 | ${NETWORKMANAGER_PLUGINDIR}/*.la \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 219 | ${datadir}/dbus-1/interfaces/*.xml \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 220 | " |
| 221 | |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 222 | SUMMARY:${PN}-daemon += "The NetworkManager daemon" |
| 223 | FILES:${PN}-daemon += " \ |
| 224 | ${bindir}/nm-online \ |
| 225 | ${datadir}/dbus-1 \ |
| 226 | ${datadir}/polkit-1 \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 227 | ${libdir}/NetworkManager \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 228 | ${libexecdir} \ |
| 229 | ${localstatedir}/lib/NetworkManager \ |
| 230 | ${NETWORKMANAGER_DISPATCHERDIR} \ |
| 231 | ${nonarch_base_libdir}/udev/* \ |
| 232 | ${nonarch_libdir}/firewalld \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 233 | ${nonarch_libdir}/NetworkManager/conf.d \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 234 | ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-down.d \ |
| 235 | ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-up.d \ |
| 236 | ${nonarch_libdir}/NetworkManager/dispatcher.d/no-wait.d \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 237 | ${nonarch_libdir}/NetworkManager/system-connections \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 238 | ${nonarch_libdir}/NetworkManager/VPN \ |
| 239 | ${sbindir}/NetworkManager \ |
| 240 | ${sysconfdir}/init.d/network-manager \ |
| 241 | ${sysconfdir}/NetworkManager \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 242 | ${systemd_system_unitdir} \ |
| 243 | " |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 244 | RRECOMMENDS:${PN}-daemon += "\ |
| 245 | ${NETWORKMANAGER_FIREWALL_DEFAULT} \ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 246 | ${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \ |
Andrew Geissler | 78b7279 | 2022-06-14 06:47:25 -0500 | [diff] [blame^] | 247 | " |
| 248 | INITSCRIPT_NAME:${PN}-daemon = "network-manager" |
| 249 | SYSTEMD_SERVICE:${PN}-daemon = "\ |
| 250 | NetworkManager.service \ |
| 251 | NetworkManager-dispatcher.service \ |
| 252 | " |
| 253 | RCONFLICTS:${PN}-daemon += "connman" |
| 254 | ALTERNATIVE_PRIORITY = "100" |
| 255 | ALTERNATIVE:${PN}-daemon = "${@bb.utils.contains('DISTRO_FEATURES','systemd','resolv-conf','',d)}" |
| 256 | ALTERNATIVE_TARGET[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv-conf.NetworkManager','',d)}" |
| 257 | ALTERNATIVE_LINK_NAME[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv.conf','',d)}" |
| 258 | |
| 259 | |
| 260 | # The networkmanager package is an empty meta package which weakly depends on all the compiled features. |
| 261 | # Install this package to get all plugins and related dependencies installed. Alternatively just install |
| 262 | # plugins and related dependencies e.g. by installing networkmanager-wifi or networkmanager-wwan |
| 263 | # packages to the firmware. |
| 264 | ALLOW_EMPTY:${PN} = "1" |
| 265 | RRECOMMENDS:${PN} += "\ |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 266 | ${@bb.utils.contains('PACKAGECONFIG','adsl','${PN}-adsl','',d)} \ |
| 267 | ${@bb.utils.contains('PACKAGECONFIG','bluez5','${PN}-bluetooth','',d)} \ |
| 268 | ${@bb.utils.contains('PACKAGECONFIG','cloud-setup','${PN}-cloud-setup','',d)} \ |
| 269 | ${@bb.utils.contains('PACKAGECONFIG','nmcli','${PN}-nmcli','',d)} \ |
| 270 | ${@bb.utils.contains('PACKAGECONFIG','nmtui','${PN}-nmtui','',d)} \ |
| 271 | ${@bb.utils.contains('PACKAGECONFIG','wifi','${PN}-wifi','',d)} \ |
| 272 | ${@bb.utils.contains('PACKAGECONFIG','wwan','${PN}-wwan','',d)} \ |
| 273 | ${@bb.utils.contains('PACKAGECONFIG','ovs','${PN}-ovs','',d)} \ |
| 274 | ${@bb.utils.contains('PACKAGECONFIG','ppp','${PN}-ppp','',d)} \ |
| 275 | " |
Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 276 | |
| 277 | do_install:append() { |
| 278 | install -Dm 0755 ${WORKDIR}/${BPN}.initd ${D}${sysconfdir}/init.d/network-manager |
| 279 | |
| 280 | rm -rf ${D}/run ${D}${localstatedir}/run |
| 281 | |
| 282 | if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then |
| 283 | # For read-only filesystem, do not create links during bootup |
| 284 | ln -sf ../run/NetworkManager/resolv.conf ${D}${sysconfdir}/resolv-conf.NetworkManager |
| 285 | |
| 286 | # systemd v210 and newer do not need this rule file |
| 287 | rm ${D}/${nonarch_base_libdir}/udev/rules.d/84-nm-drivers.rules |
| 288 | fi |
| 289 | |
| 290 | # Enable iwd if compiled |
| 291 | if ${@bb.utils.contains('PACKAGECONFIG','iwd','true','false',d)}; then |
| 292 | install -Dm 0644 ${WORKDIR}/enable-iwd.conf ${D}${libdir}/NetworkManager/conf.d/enable-iwd.conf |
| 293 | fi |
| 294 | |
| 295 | # Enable dhcpd if compiled |
| 296 | if ${@bb.utils.contains('PACKAGECONFIG','dhcpcd','true','false',d)}; then |
| 297 | install -Dm 0644 ${WORKDIR}/enable-dhcpcd.conf ${D}${libdir}/NetworkManager/conf.d/enable-dhcpcd.conf |
| 298 | fi |
| 299 | } |