| Andrew Geissler | 7e0e3c0 | 2022-02-25 20:34:39 +0000 | [diff] [blame^] | 1 | require glib.inc |
| 2 | |
| 3 | PE = "1" |
| 4 | |
| 5 | SHRT_VER = "${@oe.utils.trim_version("${PV}", 2)}" |
| 6 | |
| 7 | SRC_URI = "${GNOME_MIRROR}/glib/${SHRT_VER}/glib-${PV}.tar.xz \ |
| 8 | file://run-ptest \ |
| 9 | file://0001-Fix-DATADIRNAME-on-uclibc-Linux.patch \ |
| 10 | file://Enable-more-tests-while-cross-compiling.patch \ |
| 11 | file://0001-Remove-the-warning-about-deprecated-paths-in-schemas.patch \ |
| 12 | file://0001-Install-gio-querymodules-as-libexec_PROGRAM.patch \ |
| 13 | file://0001-Do-not-ignore-return-value-of-write.patch \ |
| 14 | file://0010-Do-not-hardcode-python-path-into-various-tools.patch \ |
| 15 | file://0001-Set-host_machine-correctly-when-building-with-mingw3.patch \ |
| 16 | file://0001-Do-not-write-bindir-into-pkg-config-files.patch \ |
| 17 | file://0001-meson-Run-atomics-test-on-clang-as-well.patch \ |
| 18 | file://0001-gio-tests-resources.c-comment-out-a-build-host-only-.patch \ |
| 19 | file://0001-gio-tests-codegen.py-bump-timeout-to-100-seconds.patch \ |
| 20 | " |
| 21 | SRC_URI:append:class-native = " file://relocate-modules.patch" |
| 22 | |
| 23 | SRC_URI[sha256sum] = "ab3d176f3115dcc4e5d02db795984e04e4f4b48d836252e23e8c468e9d423c33" |
| 24 | |
| 25 | # Find any meson cross files in FILESPATH that are relevant for the current |
| 26 | # build (using siteinfo) and add them to EXTRA_OEMESON. |
| 27 | inherit siteinfo |
| 28 | def find_meson_cross_files(d): |
| 29 | if bb.data.inherits_class('native', d): |
| 30 | return "" |
| 31 | |
| 32 | thisdir = os.path.normpath(d.getVar("THISDIR")) |
| 33 | import collections |
| 34 | sitedata = siteinfo_data(d) |
| 35 | # filename -> found |
| 36 | files = collections.OrderedDict() |
| 37 | for path in d.getVar("FILESPATH").split(":"): |
| 38 | for element in sitedata: |
| 39 | filename = os.path.normpath(os.path.join(path, "meson.cross.d", element)) |
| 40 | sanitized_path = filename.replace(thisdir, "${THISDIR}") |
| 41 | if sanitized_path == filename: |
| 42 | if os.path.exists(filename): |
| 43 | bb.error("Cannot add '%s' to --cross-file, because it's not relative to THISDIR '%s' and sstate signature would contain this full path" % (filename, thisdir)) |
| 44 | continue |
| 45 | files[filename.replace(thisdir, "${THISDIR}")] = os.path.exists(filename) |
| 46 | |
| 47 | items = ["--cross-file=" + k for k,v in files.items() if v] |
| 48 | d.appendVar("EXTRA_OEMESON", " " + " ".join(items)) |
| 49 | items = ["%s:%s" % (k, "True" if v else "False") for k,v in files.items()] |
| 50 | d.appendVarFlag("do_configure", "file-checksums", " " + " ".join(items)) |
| 51 | |
| 52 | python () { |
| 53 | find_meson_cross_files(d) |
| 54 | } |