| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 1 | SUMMARY = "Hardware accelerated JPEG compression/decompression library" |
| 2 | DESCRIPTION = "libjpeg-turbo is a derivative of libjpeg that uses SIMD instructions (MMX, SSE2, NEON) to accelerate baseline JPEG compression and decompression" |
| 3 | HOMEPAGE = "http://libjpeg-turbo.org/" |
| 4 | |
| 5 | LICENSE = "BSD-3-Clause" |
| 6 | LIC_FILES_CHKSUM = "file://cdjpeg.h;endline=13;md5=8a61af33cc1c681cd5cc297150bbb5bd \ |
| 7 | file://jpeglib.h;endline=16;md5=52b5eaade8d5b6a452a7693dfe52c084 \ |
| 8 | file://djpeg.c;endline=11;md5=510b386442ab6a27ee241fc5669bc5ea \ |
| 9 | " |
| 10 | DEPENDS:append:x86-64:class-target = " nasm-native" |
| 11 | DEPENDS:append:x86:class-target = " nasm-native" |
| 12 | |
| 13 | SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}-${PV}.tar.gz \ |
| 14 | file://0001-libjpeg-turbo-fix-package_qa-error.patch \ |
| 15 | " |
| 16 | |
| Patrick Williams | 864cc43 | 2023-02-09 14:54:44 -0600 | [diff] [blame^] | 17 | SRC_URI[sha256sum] = "bc12bc9dce55300c6bf4342bc233bcc26bd38bf289eedf147360d731c668ddaf" |
| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 18 | UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/libjpeg-turbo/files/" |
| 19 | UPSTREAM_CHECK_REGEX = "/libjpeg-turbo/files/(?P<pver>(\d+[\.\-_]*)+)/" |
| 20 | |
| 21 | PE = "1" |
| 22 | |
| 23 | # Drop-in replacement for jpeg |
| 24 | PROVIDES = "jpeg" |
| 25 | RPROVIDES:${PN} += "jpeg" |
| 26 | RREPLACES:${PN} += "jpeg" |
| 27 | RCONFLICTS:${PN} += "jpeg" |
| 28 | |
| 29 | inherit cmake pkgconfig |
| 30 | |
| 31 | export NASMENV = "--reproducible --debug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}" |
| 32 | |
| 33 | # Add nasm-native dependency consistently for all build arches is hard |
| 34 | EXTRA_OECMAKE:append:class-native = " -DWITH_SIMD=False" |
| 35 | EXTRA_OECMAKE:append:class-nativesdk = " -DWITH_SIMD=False" |
| 36 | |
| 37 | # Work around missing x32 ABI support |
| 38 | EXTRA_OECMAKE:append:class-target = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", "-DWITH_SIMD=False", "", d)}" |
| 39 | |
| 40 | # Work around missing non-floating point ABI support in MIPS |
| 41 | EXTRA_OECMAKE:append:class-target = " ${@bb.utils.contains("MIPSPKGSFX_FPU", "-nf", "-DWITH_SIMD=False", "", d)}" |
| 42 | |
| 43 | EXTRA_OECMAKE:append:class-target:arm = " ${@bb.utils.contains("TUNE_FEATURES", "neon", "", "-DWITH_SIMD=False", d)}" |
| 44 | EXTRA_OECMAKE:append:class-target:armeb = " ${@bb.utils.contains("TUNE_FEATURES", "neon", "", "-DWITH_SIMD=False", d)}" |
| 45 | |
| 46 | # Provide a workaround if Altivec unit is not present in PPC |
| 47 | EXTRA_OECMAKE:append:class-target:powerpc = " ${@bb.utils.contains("TUNE_FEATURES", "altivec", "", "-DWITH_SIMD=False", d)}" |
| 48 | EXTRA_OECMAKE:append:class-target:powerpc64 = " ${@bb.utils.contains("TUNE_FEATURES", "altivec", "", "-DWITH_SIMD=False", d)}" |
| 49 | EXTRA_OECMAKE:append:class-target:powerpc64le = " ${@bb.utils.contains("TUNE_FEATURES", "altivec", "", "-DWITH_SIMD=False", d)}" |
| 50 | |
| 51 | DEBUG_OPTIMIZATION:append:armv4 = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}" |
| 52 | DEBUG_OPTIMIZATION:append:armv5 = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}" |
| 53 | |
| 54 | PACKAGES =+ "jpeg-tools libturbojpeg" |
| 55 | |
| 56 | DESCRIPTION:jpeg-tools = "The jpeg-tools package includes client programs to access libjpeg functionality. These tools allow for the compression, decompression, transformation and display of JPEG files and benchmarking of the libjpeg library." |
| 57 | FILES:jpeg-tools = "${bindir}/*" |
| 58 | |
| 59 | DESCRIPTION:libturbojpeg = "A SIMD-accelerated JPEG codec which provides only TurboJPEG APIs" |
| 60 | FILES:libturbojpeg = "${libdir}/libturbojpeg.so.*" |
| 61 | |
| 62 | BBCLASSEXTEND = "native nativesdk" |