| Patrick Williams | 8dd6848 | 2022-10-04 07:57:18 -0500 | [diff] [blame^] | 1 | SUMMARY = "v4l2 and IR applications" |
| 2 | LICENSE = "GPL-2.0-only & LGPL-2.1-only" |
| 3 | LIC_FILES_CHKSUM = "file://COPYING;md5=48da9957849056017dc568bbc43d8975 \ |
| 4 | file://COPYING.libv4l;md5=d749e86a105281d7a44c2328acebc4b0" |
| 5 | PROVIDES = "libv4l media-ctl" |
| 6 | |
| 7 | DEPENDS = "jpeg \ |
| 8 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11', '', d)} \ |
| 9 | ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \ |
| 10 | ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa-lib', '', d)} \ |
| 11 | ${@bb.utils.contains_any('PACKAGECONFIG', 'qv4l2 qvidcap', 'qtbase qtbase-native', '', d)}" |
| 12 | |
| 13 | DEPENDS:append:libc-musl = " argp-standalone" |
| 14 | DEPENDS:append:class-target = " udev" |
| 15 | LDFLAGS:append = " -pthread" |
| 16 | |
| 17 | inherit autotools gettext pkgconfig |
| 18 | |
| 19 | PACKAGECONFIG ??= "media-ctl" |
| 20 | PACKAGECONFIG[media-ctl] = "--enable-v4l-utils,--disable-v4l-utils,," |
| 21 | PACKAGECONFIG[qv4l2] = ",--disable-qv4l2" |
| 22 | PACKAGECONFIG[qvidcap] = ",--disable-qvidcap" |
| 23 | |
| 24 | SRC_URI = "\ |
| 25 | git://git.linuxtv.org/v4l-utils.git;protocol=https;branch=master \ |
| 26 | file://0001-Revert-media-ctl-Don-t-install-libmediactl-and-libv4.patch \ |
| 27 | file://0002-original-patch-mediactl-pkgconfig.patch \ |
| 28 | file://0003-original-patch-export-mediactl-headers.patch \ |
| 29 | file://0004-Do-not-use-getsubopt.patch \ |
| 30 | " |
| 31 | |
| 32 | SRCREV = "fd544473800d02e90bc289434cc44e5aa8fadd0f" |
| 33 | |
| 34 | S = "${WORKDIR}/git" |
| 35 | B = "${S}" |
| 36 | |
| 37 | do_configure:prepend() { |
| 38 | ${S}/bootstrap.sh |
| 39 | } |
| 40 | |
| 41 | SRC_URI[md5sum] = "8aa73287320a49e9170a8255d7b2c7e6" |
| 42 | SRC_URI[sha256sum] = "65c6fbe830a44ca105c443b027182c1b2c9053a91d1e72ad849dfab388b94e31" |
| 43 | |
| 44 | EXTRA_OECONF = "--enable-shared --with-udevdir=${base_libdir}/udev \ |
| 45 | --disable-v4l2-compliance-32 --disable-v4l2-ctl-32" |
| 46 | |
| 47 | VIRTUAL-RUNTIME_ir-keytable-keymaps ?= "rc-keymaps" |
| 48 | |
| 49 | PACKAGES =+ "media-ctl ir-keytable rc-keymaps libv4l libv4l-dev qv4l2 qvidcap" |
| 50 | |
| 51 | RPROVIDES:${PN}-dbg += "libv4l-dbg" |
| 52 | |
| 53 | FILES:media-ctl = "${bindir}/media-ctl ${libdir}/libmediactl.so.*" |
| 54 | FILES:qv4l2 = "\ |
| 55 | ${bindir}/qv4l2 \ |
| 56 | ${datadir}/applications/qv4l2.desktop \ |
| 57 | ${datadir}/icons/hicolor/*/apps/qv4l2.* \ |
| 58 | " |
| 59 | FILES:qvidcap = "\ |
| 60 | ${bindir}/qvidcap \ |
| 61 | ${datadir}/applications/qvidcap.desktop \ |
| 62 | ${datadir}/icons/hicolor/*/apps/qvidcap.* \ |
| 63 | " |
| 64 | |
| 65 | FILES:ir-keytable = "${bindir}/ir-keytable ${base_libdir}/udev/rules.d/*-infrared.rules" |
| 66 | RDEPENDS:ir-keytable += "${VIRTUAL-RUNTIME_ir-keytable-keymaps}" |
| 67 | RDEPENDS:qv4l2 += "\ |
| 68 | ${@bb.utils.contains('PACKAGECONFIG', 'qv4l2', 'qtbase', '', d)}" |
| 69 | RDEPENDS:qvidcap += "\ |
| 70 | ${@bb.utils.contains('PACKAGECONFIG', 'qvidcap', 'qtbase', '', d)}" |
| 71 | |
| 72 | FILES:rc-keymaps = "${sysconfdir}/rc* ${base_libdir}/udev/rc*" |
| 73 | |
| 74 | FILES:${PN} = "${bindir} ${sbindir}" |
| 75 | |
| 76 | FILES:libv4l += "${libdir}/libv4l*${SOLIBS} ${libdir}/libv4l/*.so ${libdir}/libv4l/plugins/*.so \ |
| 77 | ${libdir}/libdvbv5*${SOLIBS} \ |
| 78 | ${libdir}/libv4l/*-decomp" |
| 79 | |
| 80 | FILES:libv4l-dev += "${includedir} ${libdir}/pkgconfig \ |
| 81 | ${libdir}/libv4l*${SOLIBSDEV} ${libdir}/*.la \ |
| 82 | ${libdir}/v4l*${SOLIBSDEV} ${libdir}/libv4l/*.la ${libdir}/libv4l/plugins/*.la" |
| 83 | |
| 84 | PARALLEL_MAKE:class-native = "" |
| 85 | BBCLASSEXTEND = "native" |