| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame^] | 1 | SUMMARY = "File synchronization tool" |
| 2 | HOMEPAGE = "http://rsync.samba.org/" |
| 3 | DESCRIPTION = "rsync is an open source utility that provides fast incremental file transfer." |
| 4 | BUGTRACKER = "http://rsync.samba.org/bugzilla.html" |
| 5 | SECTION = "console/network" |
| 6 | # GPL-2.0-or-later (<< 3.0.0), GPL-3.0-or-later (>= 3.0.0) |
| 7 | # Includes opennsh and xxhash dynamic link exception |
| 8 | LICENSE = "GPL-3.0-or-later" |
| 9 | LIC_FILES_CHKSUM = "file://COPYING;md5=24423708fe159c9d12be1ea29fcb18c7" |
| 10 | |
| 11 | DEPENDS = "popt" |
| 12 | |
| 13 | SRC_URI = "https://download.samba.org/pub/${BPN}/src/${BP}.tar.gz \ |
| 14 | file://rsyncd.conf \ |
| 15 | file://makefile-no-rebuild.patch \ |
| 16 | file://determism.patch \ |
| 17 | file://0001-Add-missing-prototypes-to-function-declarations.patch \ |
| 18 | file://0001-Turn-on-pedantic-errors-at-the-end-of-configure.patch \ |
| 19 | " |
| 20 | SRC_URI[sha256sum] = "2ac4d21635cdf791867bc377c35ca6dda7f50d919a58be45057fd51600c69aba" |
| 21 | |
| 22 | # -16548 required for v3.1.3pre1. Already in v3.1.3. |
| 23 | CVE_CHECK_IGNORE += " CVE-2017-16548 " |
| 24 | |
| 25 | inherit autotools-brokensep |
| 26 | |
| 27 | PACKAGECONFIG ??= "acl attr \ |
| 28 | ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \ |
| 29 | " |
| 30 | |
| 31 | PACKAGECONFIG[acl] = "--enable-acl-support,--disable-acl-support,acl," |
| 32 | PACKAGECONFIG[attr] = "--enable-xattr-support,--disable-xattr-support,attr," |
| 33 | PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6," |
| 34 | PACKAGECONFIG[lz4] = "--enable-lz4,--disable-lz4,lz4" |
| 35 | PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl" |
| 36 | PACKAGECONFIG[xxhash] = "--enable-xxhash,--disable-xxhash,xxhash" |
| 37 | PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd" |
| 38 | |
| 39 | # By default, if crosscompiling, rsync disables a number of |
| 40 | # capabilities, hardlinking symlinks and special files (i.e. devices) |
| 41 | CACHED_CONFIGUREVARS += "rsync_cv_can_hardlink_special=yes rsync_cv_can_hardlink_symlink=yes" |
| 42 | |
| 43 | EXTRA_OEMAKE = 'STRIP=""' |
| 44 | EXTRA_OECONF = "--disable-md2man --with-nobody-group=nogroup" |
| 45 | |
| 46 | #| ./simd-checksum-x86_64.cpp: In function 'uint32_t get_checksum1_cpp(char*, int32_t)': |
| 47 | #| ./simd-checksum-x86_64.cpp:89:52: error: multiversioning needs 'ifunc' which is not supported on this target |
| 48 | #| 89 | __attribute__ ((target("default"))) MVSTATIC int32 get_checksum1_avx2_64(schar* buf, int32 len, int32 i, uint32* ps1, uint32* ps2) { return i; } |
| 49 | #| | ^~~~~~~~~~~~~~~~~~~~~ |
| 50 | #| ./simd-checksum-x86_64.cpp:480:1: error: use of multiversioned function without a default |
| 51 | #| 480 | } |
| 52 | #| | ^ |
| 53 | #| If you can't fix the issue, re-run ./configure with --disable-roll-simd. |
| 54 | EXTRA_OECONF:append:libc-musl = " --disable-roll-simd" |
| 55 | |
| 56 | # rsync 3.0 uses configure.sh instead of configure, and |
| 57 | # makefile checks the existence of configure.sh |
| 58 | do_configure:prepend () { |
| 59 | rm -f ${S}/configure ${S}/configure.sh |
| 60 | } |
| 61 | |
| 62 | do_configure:append () { |
| 63 | cp -f ${S}/configure ${S}/configure.sh |
| 64 | } |
| 65 | |
| 66 | do_install:append() { |
| 67 | install -d ${D}${sysconfdir} |
| 68 | install -m 0644 ${WORKDIR}/rsyncd.conf ${D}${sysconfdir} |
| 69 | } |
| 70 | |
| 71 | BBCLASSEXTEND = "native nativesdk" |