| Patrick Williams | 92b42cb | 2022-09-03 06:53:57 -0500 | [diff] [blame] | 1 | SUMMARY = "Hierarchical, reference counted memory pool system with destructors" |
| 2 | HOMEPAGE = "http://ldb.samba.org" |
| 3 | SECTION = "libs" |
| 4 | LICENSE = "LGPL-3.0-or-later & LGPL-2.1-or-later & GPL-3.0-or-later" |
| 5 | |
| 6 | DEPENDS += "libtdb libtalloc libtevent popt" |
| 7 | RDEPENDS:pyldb += "python3" |
| 8 | |
| 9 | SRC_URI = "http://samba.org/ftp/ldb/ldb-${PV}.tar.gz \ |
| 10 | file://0001-do-not-import-target-module-while-cross-compile.patch \ |
| 11 | file://0002-ldb-Add-configure-options-for-packages.patch \ |
| 12 | file://0001-Fix-pyext_PATTERN-for-cross-compilation.patch \ |
| 13 | file://libldb-fix-musl-libc-conflict-type-error.patch \ |
| 14 | " |
| 15 | |
| 16 | PACKAGECONFIG ??= "\ |
| 17 | ${@bb.utils.filter('DISTRO_FEATURES', 'acl', d)} \ |
| 18 | ${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'attr', '', d)} \ |
| 19 | " |
| 20 | PACKAGECONFIG[acl] = "--with-acl,--without-acl,acl" |
| 21 | PACKAGECONFIG[attr] = "--with-attr,--without-attr,attr" |
| 22 | PACKAGECONFIG[ldap] = ",,openldap" |
| 23 | PACKAGECONFIG[libaio] = "--with-libaio,--without-libaio,libaio" |
| 24 | PACKAGECONFIG[libbsd] = "--with-libbsd,--without-libbsd,libbsd" |
| 25 | PACKAGECONFIG[libcap] = "--with-libcap,--without-libcap,libcap" |
| 26 | PACKAGECONFIG[valgrind] = "--with-valgrind,--without-valgrind,valgrind" |
| 27 | PACKAGECONFIG[lmdb] = ",--without-ldb-lmdb,lmdb," |
| 28 | |
| 29 | SRC_URI += "${@bb.utils.contains('PACKAGECONFIG', 'ldap', '', 'file://0003-avoid-openldap-unless-wanted.patch', d)}" |
| 30 | |
| 31 | LIC_FILES_CHKSUM = "file://pyldb.h;endline=24;md5=dfbd238cecad76957f7f860fbe9adade \ |
| 32 | file://man/ldb.3.xml;beginline=261;endline=262;md5=137f9fd61040c1505d1aa1019663fd08 \ |
| 33 | file://tools/ldbdump.c;endline=19;md5=a7d4fc5d1f75676b49df491575a86a42" |
| 34 | |
| 35 | SRC_URI[md5sum] = "b01d6913a06901c22c5bc6caedc548ac" |
| 36 | SRC_URI[sha256sum] = "f2e88dcab7b6007d92724b62f8a16e7c6e77275885c60eb4f87097e4aa4082c1" |
| 37 | |
| 38 | inherit pkgconfig waf-samba |
| 39 | |
| 40 | S = "${WORKDIR}/ldb-${PV}" |
| 41 | |
| 42 | #cross_compile cannot use preforked process, since fork process earlier than point subproces.popen |
| 43 | #to cross Popen |
| 44 | export WAF_NO_PREFORK="yes" |
| 45 | |
| 46 | EXTRA_OECONF += "--disable-rpath \ |
| 47 | --disable-rpath-install \ |
| 48 | --bundled-libraries=cmocka \ |
| 49 | --builtin-libraries=replace \ |
| 50 | --with-modulesdir=${libdir}/ldb/modules \ |
| 51 | --with-privatelibdir=${libdir}/ldb \ |
| 52 | --with-libiconv=${STAGING_DIR_HOST}${prefix}\ |
| 53 | " |
| 54 | |
| 55 | PACKAGES =+ "pyldb pyldb-dbg pyldb-dev" |
| 56 | |
| 57 | NOAUTOPACKAGEDEBUG = "1" |
| 58 | |
| 59 | FILES:${PN} += "${libdir}/ldb/*" |
| 60 | FILES:${PN}-dbg += "${bindir}/.debug/* \ |
| 61 | ${libdir}/.debug/* \ |
| 62 | ${libdir}/ldb/.debug/* \ |
| 63 | ${libdir}/ldb/modules/ldb/.debug/*" |
| 64 | |
| 65 | FILES:pyldb = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/* \ |
| 66 | ${libdir}/libpyldb-util.*.so.* \ |
| 67 | " |
| 68 | FILES:pyldb-dbg = "${libdir}/python${PYTHON_BASEVERSION}/site-packages/.debug \ |
| 69 | ${libdir}/.debug/libpyldb-util.*.so.*" |
| 70 | FILES:pyldb-dev = "${libdir}/libpyldb-util.*.so" |
| 71 | |
| 72 | # Prevent third_party/waf/waflib/Configure.py checking host's path which is |
| 73 | # incorrect for cross building. |
| 74 | export PREFIX = "/" |
| 75 | export LIBDIR = "${libdir}" |
| 76 | export BINDIR = "${bindir}" |
| 77 | |
| 78 | do_configure:prepend() { |
| 79 | # For a clean rebuild |
| 80 | rm -fr bin/ |
| 81 | } |