| Patrick Williams | b48b7b4 | 2016-08-17 15:04:38 -0500 | [diff] [blame^] | 1 | SUMMARY = "Implementation of XDG Sound Theme and Name Specifications" |
| 2 | DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name Specifications, for generating event sounds on free desktops." |
| 3 | LICENSE = "LGPLv2.1+" |
| 4 | LIC_FILES_CHKSUM = "file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \ |
| 5 | file://src/canberra.h;beginline=7;endline=24;md5=c616c687cf8da540a14f917e0d23ab03" |
| 6 | |
| 7 | DEPENDS = "libtool libvorbis" |
| 8 | |
| 9 | inherit autotools gtk-doc |
| 10 | |
| 11 | SRC_URI = " \ |
| 12 | http://0pointer.de/lennart/projects/${BPN}/${BPN}-${PV}.tar.xz \ |
| 13 | file://0001-build-gtk-and-gtk3-version-for-canberra_gtk_play.patch \ |
| 14 | " |
| 15 | SRC_URI[md5sum] = "34cb7e4430afaf6f447c4ebdb9b42072" |
| 16 | SRC_URI[sha256sum] = "c2b671e67e0c288a69fc33dc1b6f1b534d07882c2aceed37004bf48c601afa72" |
| 17 | |
| 18 | EXTRA_OECONF = "\ |
| 19 | --enable-null \ |
| 20 | --disable-oss \ |
| 21 | --disable-tdb \ |
| 22 | --disable-lynx \ |
| 23 | " |
| 24 | |
| 25 | PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES','alsa','alsa','',d)} \ |
| 26 | ${@bb.utils.contains('DISTRO_FEATURES','pulseaudio','pulseaudio','',d)} \ |
| 27 | ${@bb.utils.contains('DISTRO_FEATURES','x11','gtk gtk3','',d)} \ |
| 28 | " |
| 29 | PACKAGECONFIG[alsa] = "--enable-alsa, --disable-alsa, alsa-lib" |
| 30 | PACKAGECONFIG[pulseaudio] = "--enable-pulse, --disable-pulse, pulseaudio" |
| 31 | PACKAGECONFIG[gstreamer] = "--enable-gstreamer, --disable-gstreamer, gstreamer1.0" |
| 32 | PACKAGECONFIG[gtk] = "--enable-gtk, --disable-gtk, gtk+" |
| 33 | PACKAGECONFIG[gtk3] = "--enable-gtk3, --disable-gtk3, gtk+3" |
| 34 | |
| 35 | python populate_packages_prepend() { |
| 36 | plugindir = d.expand('${libdir}/${BPN}-${PV}/') |
| 37 | do_split_packages(d, plugindir, '^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' ) |
| 38 | do_split_packages(d, plugindir, '^libcanberra-(.*)\.la$', 'libcanberra-%s', '%s support library', extra_depends='' ) |
| 39 | } |
| 40 | |
| 41 | PACKAGES =+ "${PN}-gnome ${PN}-gtk2 ${PN}-gtk3 ${PN}-systemd" |
| 42 | PACKAGES_DYNAMIC += "^libcanberra-.*" |
| 43 | |
| 44 | FILES_${PN} = "${bindir}/ ${libdir}/${BPN}.so.*" |
| 45 | |
| 46 | FILES_${PN}-dev += "${datadir}/vala/vapi ${libdir}/*/modules/*.la ${libdir}/*/*.la" |
| 47 | |
| 48 | FILES_${PN}-dbg += "${libdir}/${BPN}-${PV}/.debug ${libdir}/gtk-*/modules/.debug" |
| 49 | |
| 50 | FILES_${PN}-gtk2 = "${libdir}/${BPN}-gtk.so.* \ |
| 51 | ${libdir}/gtk-2.0/modules/*.so \ |
| 52 | ${bindir}/canberra-gtk-play" |
| 53 | |
| 54 | # -gtk3 ships a symlink to a .so |
| 55 | INSANE_SKIP_${PN}-gtk3 = "dev-so" |
| 56 | FILES_${PN}-gtk3 = "${libdir}/${BPN}-gtk3.so.* \ |
| 57 | ${libdir}/gtk-3.0/modules/*.so \ |
| 58 | ${bindir}/canberra-gtk3-play" |
| 59 | |
| 60 | FILES_${PN}-gnome = "${libdir}/gnome-settings-daemon-3.0/ \ |
| 61 | ${datadir}/gdm/ ${datadir}/gnome/" |
| 62 | |
| 63 | FILES_${PN}-systemd = "${systemd_unitdir}/system/*.service" |