Patrick Williams | b48b7b4 | 2016-08-17 15:04:38 -0500 | [diff] [blame^] | 1 | SUMMARY = "Opencv : The Open Computer Vision Library" |
| 2 | HOMEPAGE = "http://opencv.org/" |
| 3 | SECTION = "libs" |
| 4 | |
| 5 | LICENSE = "BSD-3-Clause" |
| 6 | LIC_FILES_CHKSUM = "file://LICENSE;md5=0ea90d28b4de883d7af5e6711f14f7bf" |
| 7 | |
| 8 | ARM_INSTRUCTION_SET_armv4 = "arm" |
| 9 | ARM_INSTRUCTION_SET_armv5 = "arm" |
| 10 | |
| 11 | DEFAULT_PREFERENCE = "-1" |
| 12 | |
| 13 | DEPENDS = "python-numpy libtool swig swig-native python bzip2 zlib glib-2.0 libwebp libgphoto2 protobuf protobuf-native" |
| 14 | |
| 15 | SRCREV_opencv = "92387b1ef8fad15196dd5f7fb4931444a68bc93a" |
| 16 | SRCREV_contrib = "5409d5ad560523c85c6796cc5a009347072d883c" |
| 17 | SRCREV_party3 = "81a676001ca8075ada498583e4166079e5744668" |
| 18 | IPP_MD5 = "808b791a6eac9ed78d32a7666804320e" |
| 19 | |
| 20 | SRCREV_FORMAT = "opencv" |
| 21 | SRC_URI = "git://github.com/Itseez/opencv.git;name=opencv \ |
| 22 | git://github.com/Itseez/opencv_contrib.git;destsuffix=contrib;name=contrib \ |
| 23 | git://github.com/Itseez/opencv_3rdparty.git;branch=ippicv/master_20151201;destsuffix=party3;name=party3 \ |
| 24 | file://0001-3rdparty-ippicv-Use-pre-downloaded-ipp.patch \ |
| 25 | file://fixpkgconfig.patch" |
| 26 | |
| 27 | PV = "3.1+git${SRCPV}" |
| 28 | |
| 29 | S = "${WORKDIR}/git" |
| 30 | |
| 31 | do_unpack_extra() { |
| 32 | tar xzf ${WORKDIR}/party3/ippicv/ippicv_linux_20151201.tgz -C ${WORKDIR} |
| 33 | } |
| 34 | addtask unpack_extra after do_unpack before do_patch |
| 35 | |
| 36 | EXTRA_OECMAKE = "-DPYTHON2_NUMPY_INCLUDE_DIRS:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include \ |
| 37 | -DOPENCV_EXTRA_MODULES_PATH=${WORKDIR}/contrib/modules \ |
| 38 | -DWITH_1394=OFF \ |
| 39 | -DCMAKE_SKIP_RPATH=ON \ |
| 40 | -DOPENCV_ICV_PACKAGE_DOWNLOADED=${IPP_MD5} \ |
| 41 | -DOPENCV_ICV_PATH=${WORKDIR}/ippicv_lnx \ |
| 42 | ${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \ |
| 43 | ${@bb.utils.contains("TARGET_CC_ARCH", "-msse4.1", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1 -DENABLE_SSE41=1", "", d)} \ |
| 44 | ${@bb.utils.contains("TARGET_CC_ARCH", "-msse4.2", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1 -DENABLE_SSE41=1 -DENABLE_SSE42=1", "", d)} \ |
| 45 | ${@base_conditional("libdir", "/usr/lib64", "-DLIB_SUFFIX=64", "", d)} \ |
| 46 | ${@base_conditional("libdir", "/usr/lib32", "-DLIB_SUFFIX=32", "", d)} \ |
| 47 | " |
| 48 | EXTRA_OECMAKE_append_x86 = " -DX86=ON" |
| 49 | |
| 50 | PACKAGECONFIG ??= "eigen jpeg png tiff v4l libv4l gstreamer samples tbb \ |
| 51 | ${@bb.utils.contains("DISTRO_FEATURES", "x11", "gtk", "", d)} \ |
| 52 | ${@bb.utils.contains("LICENSE_FLAGS_WHITELIST", "commercial", "libav", "", d)}" |
| 53 | |
| 54 | PACKAGECONFIG[amdblas] = "-DWITH_OPENCLAMDBLAS=ON,-DWITH_OPENCLAMDBLAS=OFF,libclamdblas," |
| 55 | PACKAGECONFIG[amdfft] = "-DWITH_OPENCLAMDFFT=ON,-DWITH_OPENCLAMDFFT=OFF,libclamdfft," |
| 56 | PACKAGECONFIG[eigen] = "-DWITH_EIGEN=ON,-DWITH_EIGEN=OFF,libeigen," |
| 57 | PACKAGECONFIG[gstreamer] = "-DWITH_GSTREAMER=ON,-DWITH_GSTREAMER=OFF,gstreamer1.0 gstreamer1.0-plugins-base," |
| 58 | PACKAGECONFIG[gtk] = "-DWITH_GTK=ON,-DWITH_GTK=OFF,gtk+3," |
| 59 | PACKAGECONFIG[jasper] = "-DWITH_JASPER=ON,-DWITH_JASPER=OFF,jasper," |
| 60 | PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON,-DWITH_JPEG=OFF,jpeg," |
| 61 | PACKAGECONFIG[libav] = "-DWITH_FFMPEG=ON,-DWITH_FFMPEG=OFF,libav," |
| 62 | PACKAGECONFIG[libv4l] = "-DWITH_LIBV4L=ON,-DWITH_LIBV4L=OFF,v4l-utils," |
| 63 | PACKAGECONFIG[opencl] = "-DWITH_OPENCL=ON,-DWITH_OPENCL=OFF,opencl-headers," |
| 64 | PACKAGECONFIG[oracle-java] = "-DJAVA_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_INCLUDE_PATH2=${JAVA_HOME}/include/linux -DJAVA_AWT_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_AWT_LIBRARY=${JAVA_HOME}/lib/amd64/libjawt.so -DJAVA_JVM_LIBRARY=${JAVA_HOME}/lib/amd64/server/libjvm.so,,ant-native oracle-jse-jdk oracle-jse-jdk-native," |
| 65 | PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng," |
| 66 | PACKAGECONFIG[samples] = "-DBUILD_EXAMPLES=ON -DINSTALL_PYTHON_EXAMPLES=ON,-DBUILD_EXAMPLES=OFF,," |
| 67 | PACKAGECONFIG[tbb] = "-DWITH_TBB=ON,-DWITH_TBB=OFF,tbb," |
| 68 | PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff," |
| 69 | PACKAGECONFIG[v4l] = "-DWITH_V4L=ON,-DWITH_V4L=OFF,v4l-utils," |
| 70 | |
| 71 | inherit distutils-base pkgconfig cmake |
| 72 | |
| 73 | export BUILD_SYS |
| 74 | export HOST_SYS |
| 75 | export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}" |
| 76 | export PYTHON="${STAGING_BINDIR_NATIVE}/python" |
| 77 | export JAVA_HOME="${STAGING_DIR_NATIVE}/usr/bin/java" |
| 78 | export ANT_DIR="${STAGING_DIR_NATIVE}/usr/share/ant/" |
| 79 | |
| 80 | TARGET_CC_ARCH += "-I${S}/include " |
| 81 | |
| 82 | PACKAGES += "${PN}-samples-dbg ${PN}-samples ${PN}-apps python-opencv \ |
| 83 | ${@bb.utils.contains('PACKAGECONFIG', 'oracle-java', '${PN}-java-dbg ${PN}-java', '', d)}" |
| 84 | |
| 85 | python populate_packages_prepend () { |
| 86 | cv_libdir = d.expand('${libdir}') |
| 87 | cv_libdir_dbg = d.expand('${libdir}/.debug') |
| 88 | do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True) |
| 89 | do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev') |
| 90 | do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev') |
| 91 | do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True) |
| 92 | |
| 93 | pn = d.getVar('PN', 1) |
| 94 | metapkg = pn + '-dev' |
| 95 | d.setVar('ALLOW_EMPTY_' + metapkg, "1") |
| 96 | blacklist = [ metapkg ] |
| 97 | metapkg_rdepends = [ ] |
| 98 | packages = d.getVar('PACKAGES', 1).split() |
| 99 | for pkg in packages[1:]: |
| 100 | if not pkg in blacklist and not pkg in metapkg_rdepends and pkg.endswith('-dev'): |
| 101 | metapkg_rdepends.append(pkg) |
| 102 | d.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rdepends)) |
| 103 | |
| 104 | metapkg = pn |
| 105 | blacklist = [ metapkg ] |
| 106 | metapkg_rdepends = [ ] |
| 107 | for pkg in packages[1:]: |
| 108 | if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.endswith('-dbg') and not pkg.endswith('-doc') and not pkg.endswith('-locale'): |
| 109 | metapkg_rdepends.append(pkg) |
| 110 | bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d) |
| 111 | |
| 112 | } |
| 113 | |
| 114 | PACKAGES_DYNAMIC += "^libopencv-.*" |
| 115 | |
| 116 | FILES_${PN} = "" |
| 117 | FILES_${PN}-apps = "${bindir}/* ${datadir}/OpenCV" |
| 118 | FILES_${PN}-dbg += "${libdir}/.debug" |
| 119 | FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig" |
| 120 | FILES_${PN}-doc = "${datadir}/OpenCV/doc" |
| 121 | FILES_${PN}-java = "${datadir}/OpenCV/java" |
| 122 | FILES_${PN}-java-dbg = "${datadir}/OpenCV/java/.debug/" |
| 123 | FILES_${PN}-samples = "${datadir}/OpenCV/samples/" |
| 124 | FILES_${PN}-samples-dbg = "${datadir}/OpenCV/samples/bin/.debug" |
| 125 | |
| 126 | INSANE_SKIP_${PN}-apps = "staticdev" |
| 127 | INSANE_SKIP_${PN}-java = "libdir" |
| 128 | INSANE_SKIP_${PN}-java-dbg = "libdir" |
| 129 | |
| 130 | ALLOW_EMPTY_${PN} = "1" |
| 131 | |
| 132 | SUMMARY_python-opencv = "Python bindings to opencv" |
| 133 | FILES_python-opencv = "${PYTHON_SITEPACKAGES_DIR}/*" |
| 134 | RDEPENDS_python-opencv = "python-core python-numpy" |
| 135 | |
| 136 | do_install_append() { |
| 137 | cp ${S}/include/opencv/*.h ${D}${includedir}/opencv/ |
| 138 | sed -i '/blobtrack/d' ${D}${includedir}/opencv/cvaux.h |
| 139 | |
| 140 | # Move Python files into correct library folder (for multilib build) |
| 141 | if [ "$libdir" != "/usr/lib" ]; then |
| 142 | mv ${D}/usr/lib/* ${D}/${libdir}/ |
| 143 | rm -rf ${D}/usr/lib |
| 144 | fi |
| 145 | |
| 146 | install -d ${D}${datadir}/OpenCV/samples/bin/ |
| 147 | cp -f bin/*-tutorial-* bin/*-example-* ${D}${datadir}/OpenCV/samples/bin/ |
| 148 | } |
| 149 | |