| Patrick Williams | c0f7c04 | 2017-02-23 20:41:17 -0600 | [diff] [blame^] | 1 | SUMMARY = "WebP is an image format designed for the Web" |
| 2 | DESCRIPTION = "WebP is a method of lossy and lossless compression that can be \ |
| 3 | used on a large variety of photographic, translucent and \ |
| 4 | graphical images found on the web. The degree of lossy \ |
| 5 | compression is adjustable so a user can choose the trade-off \ |
| 6 | between file size and image quality. WebP typically achieves \ |
| 7 | an average of 30% more compression than JPEG and JPEG 2000, \ |
| 8 | without loss of image quality." |
| 9 | HOMEPAGE = "https://developers.google.com/speed/webp/" |
| 10 | SECTION = "libs" |
| 11 | |
| 12 | LICENSE = "BSD" |
| 13 | LIC_FILES_CHKSUM = "file://COPYING;md5=6e8dee932c26f2dab503abf70c96d8bb \ |
| 14 | file://PATENTS;md5=c6926d0cb07d296f886ab6e0cc5a85b7" |
| 15 | |
| 16 | SRC_URI = "http://downloads.webmproject.org/releases/webp/${BP}.tar.gz" |
| 17 | SRC_URI[md5sum] = "3d7db92ebba5b4f679413d25c6040881" |
| 18 | SRC_URI[sha256sum] = "6ad66c6fcd60a023de20b6856b03da8c7d347269d76b1fd9c3287e8b5e8813df" |
| 19 | |
| 20 | UPSTREAM_CHECK_URI = "http://downloads.webmproject.org/releases/webp/index.html" |
| 21 | |
| 22 | EXTRA_OECONF = " \ |
| 23 | --disable-experimental \ |
| 24 | --disable-wic \ |
| 25 | --enable-libwebpmux \ |
| 26 | --enable-libwebpdemux \ |
| 27 | --enable-threading \ |
| 28 | " |
| 29 | # Do not trust configure to determine if neon is available. |
| 30 | # |
| 31 | EXTRA_OECONF_append_arm = " \ |
| 32 | ${@bb.utils.contains("TUNE_FEATURES","neon","--enable-neon","--disable-neon",d)} \ |
| 33 | " |
| 34 | |
| 35 | inherit autotools lib_package |
| 36 | |
| 37 | PACKAGECONFIG ??= "" |
| 38 | |
| 39 | # libwebpdecoder is a subset of libwebp, don't build it unless requested |
| 40 | PACKAGECONFIG[decoder] = "--enable-libwebpdecoder,--disable-libwebpdecoder" |
| 41 | |
| 42 | # Apply for examples programs: cwebp and dwebp |
| 43 | PACKAGECONFIG[gif] = "--enable-gif,--disable-gif,giflib" |
| 44 | PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg" |
| 45 | PACKAGECONFIG[png] = "--enable-png,--disable-png,,libpng" |
| 46 | PACKAGECONFIG[tiff] = "--enable-tiff,--disable-tiff,tiff" |
| 47 | |
| 48 | # Apply only for example program vwebp |
| 49 | PACKAGECONFIG[gl] = "--enable-gl,--disable-gl,mesa-glut" |
| 50 | |
| 51 | PACKAGES =+ "${PN}-gif2webp" |
| 52 | |
| 53 | DESCRIPTION_${PN}-gif2webp = "Simple tool to convert animated GIFs to WebP" |
| 54 | FILES_${PN}-gif2webp = "${bindir}/gif2webp" |