| Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame^] | 1 | SUMMARY = "eudev is a fork of systemd's udev" |
| 2 | HOMEPAGE = "https://github.com/eudev-project/eudev" |
| 3 | DESCRIPTION = "eudev is Gentoo's fork of udev, systemd's device file manager for the Linux kernel. It manages device nodes in /dev and handles all user space actions when adding or removing devices." |
| 4 | LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later" |
| 5 | LICENSE:libudev = "LGPL-2.1-or-later" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe" |
| 7 | |
| 8 | DEPENDS = "gperf-native" |
| 9 | |
| 10 | PROVIDES = "udev" |
| 11 | |
| 12 | SRC_URI = "https://github.com/eudev-project/${BPN}/releases/download/v${PV}/${BP}.tar.gz \ |
| 13 | file://init \ |
| 14 | file://local.rules \ |
| 15 | file://0001-build-Remove-dead-g-i-r-configuration.patch \ |
| 16 | " |
| 17 | |
| 18 | SRC_URI[sha256sum] = "19847cafec67897da855fde56f9dc7d92e21c50e450aa79068a7e704ed44558b" |
| 19 | |
| 20 | UPSTREAM_CHECK_URI = "https://github.com/eudev-project/eudev/releases" |
| 21 | UPSTREAM_CHECK_REGEX = "eudev-(?P<pver>\d+(\.\d+)+)\.tar" |
| 22 | |
| 23 | inherit autotools update-rc.d qemu pkgconfig features_check manpages |
| 24 | |
| 25 | CONFLICT_DISTRO_FEATURES = "systemd" |
| 26 | |
| 27 | EXTRA_OECONF = " \ |
| 28 | --sbindir=${base_sbindir} \ |
| 29 | --with-rootlibdir=${base_libdir} \ |
| 30 | --with-rootlibexecdir=${nonarch_base_libdir}/udev \ |
| 31 | --with-rootprefix= \ |
| 32 | " |
| 33 | |
| 34 | PACKAGECONFIG ?= "blkid hwdb kmod \ |
| 35 | ${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \ |
| 36 | " |
| 37 | PACKAGECONFIG[blkid] = "--enable-blkid,--disable-blkid,util-linux" |
| 38 | PACKAGECONFIG[hwdb] = "--enable-hwdb,--disable-hwdb" |
| 39 | PACKAGECONFIG[kmod] = "--enable-kmod,--disable-kmod,kmod" |
| 40 | PACKAGECONFIG[manpages] = "--enable-manpages,--disable-manpages" |
| 41 | PACKAGECONFIG[rule-generator] = "--enable-rule-generator,--disable-rule-generator" |
| 42 | PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux" |
| 43 | |
| 44 | do_install:append() { |
| 45 | install -d ${D}${sysconfdir}/init.d |
| 46 | install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev |
| 47 | sed -i s%@UDEVD@%${base_sbindir}/udevd% ${D}${sysconfdir}/init.d/udev |
| 48 | sed -i s%@KMOD@%${base_bindir}/kmod% ${D}${sysconfdir}/init.d/udev |
| 49 | |
| 50 | install -d ${D}${sysconfdir}/udev/rules.d |
| 51 | install -m 0644 ${WORKDIR}/local.rules ${D}${sysconfdir}/udev/rules.d/local.rules |
| 52 | |
| 53 | # Use classic network interface naming scheme |
| 54 | touch ${D}${sysconfdir}/udev/rules.d/80-net-name-slot.rules |
| 55 | } |
| 56 | |
| 57 | do_install:prepend:class-target () { |
| 58 | # Remove references to buildmachine |
| 59 | sed -i -e 's:${RECIPE_SYSROOT_NATIVE}::g' \ |
| 60 | ${B}/src/udev/keyboard-keys-from-name.h |
| 61 | } |
| 62 | |
| 63 | INITSCRIPT_NAME = "udev" |
| 64 | INITSCRIPT_PARAMS = "start 04 S ." |
| 65 | |
| 66 | PACKAGE_BEFORE_PN = "libudev ${PN}-hwdb" |
| 67 | |
| 68 | FILES:${PN} += "${nonarch_base_libdir}/udev" |
| 69 | FILES:libudev = "${base_libdir}/libudev.so.*" |
| 70 | FILES:${PN}-hwdb = "${sysconfdir}/udev/hwdb.d" |
| 71 | |
| 72 | RDEPENDS:${PN}-hwdb += "eudev" |
| 73 | RDEPENDS:${PN} += "kmod" |
| 74 | |
| 75 | RPROVIDES:${PN} = "hotplug udev" |
| 76 | RPROVIDES:${PN}-hwdb += "udev-hwdb" |
| 77 | |
| 78 | PACKAGE_WRITE_DEPS += "qemu-native" |
| 79 | pkg_postinst:${PN}-hwdb () { |
| 80 | if test -n "$D"; then |
| 81 | $INTERCEPT_DIR/postinst_intercept update_udev_hwdb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} |
| 82 | else |
| 83 | udevadm hwdb --update |
| 84 | fi |
| 85 | } |
| 86 | |
| 87 | pkg_prerm:${PN}-hwdb () { |
| 88 | rm -f $D${sysconfdir}/udev/hwdb.bin |
| 89 | } |