subprojects/callback-manager/meson.build

project(
    'callback-manager',
    'cpp',
    version: '1.1.1',
    meson_version: '>=1.1.1',
    default_options: ['cpp_std=c++23'],
)

# Compiler flags
cpp_args = [
    '-Werror',
    '-Wall',
    '-Wextra',
    '-Wshadow',
    '-Wnon-virtual-dtor',
    '-Wold-style-cast',
    '-Wcast-align',
    '-Wunused',
    '-Woverloaded-virtual',
    '-Wpedantic',
    '-Wconversion',
    '-Wmisleading-indentation',
    '-Wduplicated-cond',
    '-Wduplicated-branches',
    '-Wlogical-op',
    '-Wnull-dereference',
    '-Wuseless-cast',
    '-Wdouble-promotion',
    '-Wformat=2',
    '-fno-rtti',
]

# Definitions
add_project_arguments(
    '-DBOOST_ERROR_CODE_HEADER_ONLY',
    '-DBOOST_SYSTEM_NO_DEPRECATED',
    '-DBOOST_ALL_NO_LIB',
    '-DBOOST_NO_RTTI',
    '-DBOOST_NO_TYPEID',
    '-DBOOST_ASIO_DISABLE_THREADS',
    language: 'cpp',
)

# Include directories
inc = include_directories('include')

boost = dependency('boost', version: '1.86.0', required: false)
sdbusplus = dependency('sdbusplus', required: true)

executable(
    'callback-manager',
    'src/callback_manager.cpp',
    include_directories: inc,
    cpp_args: cpp_args,
    dependencies: [boost, sdbusplus],
)

# Systemd service files
systemd_system_unit_dir = dependency('systemd').get_variable(
    'systemdsystemunitdir',
)

install_data(
    'service_files/callback-manager.service',
    install_dir: systemd_system_unit_dir,
)