| SUMMARY = "GNOME XSLT library" |
| HOMEPAGE = "http://xmlsoft.org/XSLT/" |
| BUGTRACKER = "https://bugzilla.gnome.org/" |
| |
| LICENSE = "MIT" |
| LIC_FILES_CHKSUM = "file://Copyright;md5=0cd9a07afbeb24026c9b03aecfeba458" |
| |
| SECTION = "libs" |
| DEPENDS = "libxml2" |
| |
| SRC_URI = "http://xmlsoft.org/sources/libxslt-${PV}.tar.gz \ |
| file://0001-Fix-security-framework-bypass.patch \ |
| file://CVE-2019-13117.patch \ |
| file://CVE-2019-13118.patch \ |
| " |
| |
| SRC_URI[md5sum] = "b3bd254a03e46d58f8ad1e4559cd2c2f" |
| SRC_URI[sha256sum] = "8e36605144409df979cab43d835002f63988f3dc94d5d3537c12796db90e38c8" |
| |
| UPSTREAM_CHECK_REGEX = "libxslt-(?P<pver>\d+(\.\d+)+)\.tar" |
| |
| S = "${WORKDIR}/libxslt-${PV}" |
| |
| BINCONFIG = "${bindir}/xslt-config" |
| |
| inherit autotools pkgconfig binconfig-disabled lib_package |
| |
| do_configure_prepend () { |
| # We don't DEPEND on binutils for ansidecl.h so ensure we don't use the header. |
| # This can be removed when upgrading to 1.1.34. |
| sed -i -e 's/ansidecl.h//' ${S}/configure.ac |
| |
| # The timestamps in the 1.1.28 tarball are messed up causing this file to |
| # appear out of date. Touch it so that we don't try to regenerate it. |
| touch ${S}/doc/xsltproc.1 |
| } |
| |
| EXTRA_OECONF = "--without-python --without-debug --without-mem-debug --without-crypto --with-html-subdir=${BPN}" |
| # older versions of this recipe had ${PN}-utils |
| RPROVIDES_${PN}-bin += "${PN}-utils" |
| RCONFLICTS_${PN}-bin += "${PN}-utils" |
| RREPLACES_${PN}-bin += "${PN}-utils" |
| |
| # This is only needed until libxml can load the relocated catalog itself |
| do_install_append_class-native () { |
| create_wrapper ${D}/${bindir}/xsltproc XML_CATALOG_FILES=${sysconfdir}/xml/catalog |
| } |
| |
| FILES_${PN} += "${libdir}/libxslt-plugins" |
| FILES_${PN}-dev += "${libdir}/xsltConf.sh" |
| |
| BBCLASSEXTEND = "native nativesdk" |