| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 1 | SUMMARY = "OpenMAX IL plugins for GStreamer" |
| 2 | HOMEPAGE = "http://gstreamer.freedesktop.org/" |
| 3 | SECTION = "multimedia" |
| 4 | |
| 5 | LICENSE = "LGPLv2.1" |
| 6 | LICENSE_FLAGS = "commercial" |
| 7 | LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \ |
| 8 | file://omx/gstomx.h;beginline=1;endline=21;md5=5c8e1fca32704488e76d2ba9ddfa935f" |
| 9 | |
| 10 | SRC_URI = "https://gstreamer.freedesktop.org/src/gst-omx/gst-omx-${PV}.tar.xz" |
| 11 | |
| 12 | SRC_URI[md5sum] = "6362786d2b6cce34de08c86b7847f782" |
| 13 | SRC_URI[sha256sum] = "11ed411a2eba75610d72331eeb14ff05e2df28f4fd05cb69225a88bec6d27439" |
| 14 | |
| 15 | S = "${WORKDIR}/gst-omx-${PV}" |
| 16 | |
| 17 | DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad virtual/libomxil" |
| 18 | |
| 19 | inherit meson pkgconfig upstream-version-is-even |
| 20 | |
| 21 | GSTREAMER_1_0_OMX_TARGET ?= "bellagio" |
| 22 | GSTREAMER_1_0_OMX_CORE_NAME ?= "${libdir}/libomxil-bellagio.so.0" |
| 23 | |
| 24 | EXTRA_OEMESON += "-Dtarget=${GSTREAMER_1_0_OMX_TARGET}" |
| 25 | |
| 26 | python __anonymous () { |
| 27 | omx_target = d.getVar("GSTREAMER_1_0_OMX_TARGET") |
| 28 | if omx_target in ['generic', 'bellagio']: |
| 29 | # Bellagio headers are incomplete (they are missing the OMX_VERSION_MAJOR,# |
| 30 | # OMX_VERSION_MINOR, OMX_VERSION_REVISION, and OMX_VERSION_STEP macros); |
| 31 | # appending a directory path to gst-omx' internal OpenMAX IL headers fixes this |
| 32 | d.appendVar("CFLAGS", " -I${S}/omx/openmax") |
| 33 | elif omx_target == "rpi": |
| 34 | # Dedicated Raspberry Pi OpenMAX IL support makes this package machine specific |
| 35 | d.setVar("PACKAGE_ARCH", d.getVar("MACHINE_ARCH")) |
| 36 | } |
| 37 | |
| 38 | set_omx_core_name() { |
| 39 | sed -i -e "s;^core-name=.*;core-name=${GSTREAMER_1_0_OMX_CORE_NAME};" "${D}${sysconfdir}/xdg/gstomx.conf" |
| 40 | } |
| 41 | do_install[postfuncs] += " set_omx_core_name " |
| 42 | |
| 43 | FILES_${PN} += "${libdir}/gstreamer-1.0/*.so" |
| 44 | FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a" |
| 45 | |
| 46 | VIRTUAL-RUNTIME_libomxil ?= "libomxil" |
| 47 | RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_libomxil}" |