| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 1 | SUMMARY = "Xfce4 Panel" |
| 2 | SECTION = "x11" |
| 3 | LICENSE = "GPLv2" |
| 4 | LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee" |
| 5 | DEPENDS = "garcon exo gtk+3 cairo virtual/libx11 libxml2 libwnck3 vala-native" |
| 6 | |
| 7 | inherit xfce gtk-doc gobject-introspection features_check remove-libtool mime-xdg |
| 8 | |
| 9 | REQUIRED_DISTRO_FEATURES = "x11" |
| 10 | |
| Andrew Geissler | 72956ed | 2021-01-08 16:11:14 -0600 | [diff] [blame^] | 11 | SRC_URI[sha256sum] = "5e979aeeb37d306d72858b1bc67448222ea7a68de01409055b846cd31f3cc53d" |
| Andrew Geissler | 82c905d | 2020-04-13 13:39:40 -0500 | [diff] [blame] | 12 | SRC_URI += " \ |
| 13 | file://0001-windowmenu-do-not-display-desktop-icon-when-no-windo.patch \ |
| 14 | file://0002-use-lxdm-to-replace-dm-tool.patch \ |
| 15 | " |
| 16 | |
| 17 | python populate_packages_prepend() { |
| 18 | plugin_dir = d.expand('${libdir}/xfce4/panel/plugins/') |
| 19 | plugin_name = d.expand('${PN}-plugin-%s') |
| 20 | do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name, |
| 21 | '${PN} plugin for %s', extra_depends='', prepend=True, |
| 22 | aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop', |
| 23 | '${sysconfdir}/xdg/xfce/panel/%s-*', |
| 24 | '${datadir}/icons/hicolor/48x48/apps/*-%s.png', |
| 25 | '${bindir}/*%s*']) |
| 26 | } |
| 27 | |
| 28 | PACKAGES_DYNAMIC += "^${PN}-plugin-.*" |
| 29 | |
| 30 | PACKAGES =+ "${PN}-gtk3" |
| 31 | |
| 32 | FILES_${PN} += "${libdir}/xfce4/panel/migrate \ |
| 33 | ${libdir}/xfce4/panel/wrapper-1.0" |
| 34 | |
| 35 | FILES_${PN}-dev += "${libdir}/xfce4/panel/plugins/*.la" |
| 36 | |
| 37 | FILES_${PN}-gtk3 = " \ |
| 38 | ${libdir}/libxfce4panel-2.0${SOLIBS} \ |
| 39 | ${libdir}/xfce4/panel/wrapper-2.0 \ |
| 40 | " |