| Andrew Geissler | 595f630 | 2022-01-24 19:11:47 +0000 | [diff] [blame] | 1 | SUMMARY = "System-wide Performance Profiler for Linux" |
| 2 | HOMEPAGE = "http://www.sysprof.com" |
| 3 | LICENSE = "GPLv3+" |
| 4 | LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \ |
| 5 | file://src/sysprof/sysprof-application.c;endline=17;md5=a3de8df3b0f8876dd01e1388d2d4b607" |
| 6 | |
| 7 | GNOMEBASEBUILDCLASS = "meson" |
| 8 | inherit gnomebase gnome-help gettext systemd upstream-version-is-even gsettings mime mime-xdg |
| 9 | |
| 10 | DEPENDS += " \ |
| 11 | glib-2.0-native \ |
| 12 | yelp-tools-native \ |
| 13 | libxml2-native \ |
| 14 | glib-2.0 \ |
| 15 | json-glib \ |
| 16 | " |
| 17 | |
| 18 | SRC_URI[archive.sha256sum] = "1796b81404ee75fd1ebacf54464ad7affebf62f2851eef524d9f8eac0c4a2001" |
| 19 | |
| 20 | PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'polkit', 'sysprofd', '', d)} \ |
| 21 | ${@bb.utils.contains('DISTRO_FEATURES', 'polkit', 'libsysprof', '', d)} \ |
| 22 | ${@bb.utils.contains_any('DISTRO_FEATURES', '${GTK3DISTROFEATURES}', 'gtk', '', d)}" |
| 23 | PACKAGECONFIG[gtk] = "-Denable_gtk=true,-Denable_gtk=false,gtk+3 libdazzle" |
| 24 | PACKAGECONFIG[sysprofd] = "-Dwith_sysprofd=bundled,-Dwith_sysprofd=none,polkit" |
| 25 | PACKAGECONFIG[libsysprof] = "-Dlibsysprof=true,-Dlibsysprof=false,polkit" |
| 26 | |
| 27 | EXTRA_OEMESON += "-Dsystemdunitdir=${systemd_unitdir}/system" |
| 28 | |
| 29 | SOLIBS = ".so" |
| 30 | FILES_SOLIBSDEV = "" |
| 31 | |
| 32 | SYSTEMD_SERVICE:${PN} = "${@bb.utils.contains('PACKAGECONFIG', 'sysprofd', 'sysprof2.service sysprof3.service', '', d)}" |
| 33 | |
| 34 | FILES:${PN} += " \ |
| 35 | ${datadir}/dbus-1/system-services \ |
| 36 | ${datadir}/dbus-1/system.d \ |
| 37 | ${datadir}/dbus-1/interfaces \ |
| 38 | ${datadir}/metainfo \ |
| 39 | " |