| Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 1 | SUMMARY = "Additional utilities for the opkg package manager" |
| 2 | SUMMARY_update-alternatives-opkg = "Utility for managing the alternatives system" |
| 3 | SECTION = "base" |
| 4 | HOMEPAGE = "http://git.yoctoproject.org/cgit/cgit.cgi/opkg-utils" |
| 5 | LICENSE = "GPLv2+" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \ |
| 7 | file://opkg.py;beginline=2;endline=18;md5=63ce9e6bcc445181cd9e4baf4b4ccc35" |
| 8 | PROVIDES += "${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'virtual/update-alternatives', '', d)}" |
| 9 | |
| 10 | SRC_URI = "http://git.yoctoproject.org/cgit/cgit.cgi/${BPN}/snapshot/${BPN}-${PV}.tar.gz \ |
| 11 | file://0001-Switch-all-scripts-to-use-Python-3.x.patch \ |
| 12 | file://0001-Only-use-sort-name-on-versions-of-tar-which-support-.patch \ |
| 13 | file://0002-opkg-build-Use-local-time-for-build_date-since-opkg-.patch \ |
| 14 | file://threaded-xz.patch \ |
| 15 | " |
| 16 | SRC_URI_append_class-native = " file://tar_ignore_error.patch" |
| 17 | UPSTREAM_CHECK_URI = "http://git.yoctoproject.org/cgit/cgit.cgi/opkg-utils/refs/" |
| 18 | |
| 19 | |
| 20 | SRC_URI[md5sum] = "391c1c80aca26961375dd22e1d2d0cbf" |
| 21 | SRC_URI[sha256sum] = "26b3f4dd1c1ef65f519d4cddfb35ebea41ae8af989aea2699a39783598c33769" |
| 22 | |
| 23 | TARGET_CC_ARCH += "${LDFLAGS}" |
| 24 | |
| 25 | # For native builds we use the host Python |
| 26 | PYTHONRDEPS = "python3 python3-shell python3-io python3-math python3-crypt python3-logging python3-fcntl python3-pickle python3-compression python3-stringold" |
| 27 | PYTHONRDEPS_class-native = "" |
| 28 | |
| 29 | PACKAGECONFIG = "python update-alternatives" |
| 30 | PACKAGECONFIG[python] = ",,,${PYTHONRDEPS}" |
| 31 | PACKAGECONFIG[update-alternatives] = ",,," |
| 32 | |
| 33 | do_install() { |
| 34 | oe_runmake PREFIX=${prefix} DESTDIR=${D} install |
| 35 | if ! ${@bb.utils.contains('PACKAGECONFIG', 'update-alternatives', 'true', 'false', d)}; then |
| 36 | rm -f "${D}${bindir}/update-alternatives" |
| 37 | fi |
| 38 | |
| 39 | if ! ${@bb.utils.contains('PACKAGECONFIG', 'python', 'true', 'false', d)}; then |
| 40 | grep -lZ "/usr/bin/env.*python" ${D}${bindir}/* | xargs -0 rm |
| 41 | fi |
| 42 | } |
| 43 | |
| 44 | do_install_append_class-target() { |
| 45 | if [ -e "${D}${bindir}/update-alternatives" ]; then |
| 46 | sed -i ${D}${bindir}/update-alternatives -e 's,/usr/bin,${bindir},g; s,/usr/lib,${nonarch_libdir},g' |
| 47 | fi |
| 48 | } |
| 49 | |
| 50 | # These are empty and will pull python3-dev into images where it wouldn't |
| 51 | # have been otherwise, so don't generate them. |
| 52 | PACKAGES_remove = "${PN}-dev ${PN}-staticdev" |
| 53 | |
| 54 | PACKAGES =+ "update-alternatives-opkg" |
| 55 | FILES_update-alternatives-opkg = "${bindir}/update-alternatives" |
| 56 | RPROVIDES_update-alternatives-opkg = "update-alternatives update-alternatives-cworth" |
| 57 | RREPLACES_update-alternatives-opkg = "update-alternatives-cworth" |
| 58 | RCONFLICTS_update-alternatives-opkg = "update-alternatives-cworth" |
| 59 | |
| 60 | pkg_postrm_update-alternatives-opkg() { |
| 61 | rm -rf $D${nonarch_libdir}/opkg/alternatives |
| 62 | rmdir $D${nonarch_libdir}/opkg || true |
| 63 | } |
| 64 | |
| 65 | BBCLASSEXTEND = "native nativesdk" |
| 66 | |
| 67 | CLEANBROKEN = "1" |