| Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 1 | SUMMARY = "A C implementation of the Constrained Application Protocol" |
| 2 | DESCRIPTION = "libcoap implements a lightweight application-protocol for \ |
| 3 | devices that are constrained their resources such as computing power, \ |
| 4 | RF range, memory, bandwith, or network packet sizes." |
| 5 | HOMEPAGE ="https://libcoap.net/" |
| 6 | |
| 7 | LICENSE = "BSD-2-Clause & BSD-1-Clause" |
| 8 | LIC_FILES_CHKSUM = "file://LICENSE;md5=e44b3af4925ec58e9f49b9ff143b5493" |
| 9 | |
| 10 | SRC_URI = "git://github.com/obgm/libcoap.git;branch=main;protocol=https \ |
| 11 | file://0001-libcoap-Fix-gnu-configize-error.patch \ |
| 12 | file://0001-coap_session.c-Balance-SESSIONS_ADD-and-SESSIONS_DEL.patch \ |
| 13 | file://run-ptest \ |
| 14 | " |
| 15 | SRCREV = "1da37b9abbe871675d5939395b498324ccc8ecfe" |
| 16 | |
| 17 | S = "${WORKDIR}/git" |
| 18 | |
| 19 | inherit autotools manpages pkgconfig ptest |
| 20 | |
| 21 | PACKAGECONFIG ?= "\ |
| 22 | async openssl tcp \ |
| 23 | ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)} \ |
| 24 | " |
| 25 | PACKAGECONFIG[async] = "--enable-async,--disable-async" |
| 26 | PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls,,openssl mbedtls" |
| 27 | PACKAGECONFIG[manpages] = "--enable-documentation --enable-doxygen --enable-manpages,--disable-documentation,asciidoc-native doxygen-native graphviz-native" |
| 28 | PACKAGECONFIG[mbedtls] = "--with-mbedtls,--without-mbedtls,mbedtls,,gnutls openssl" |
| 29 | PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl,,gnutls mbedtls" |
| 30 | PACKAGECONFIG[small-stack] = "--enable-small-stack,--disable-small-stack" |
| 31 | PACKAGECONFIG[tcp] = "--enable-tcp,--disable-tcp" |
| 32 | PACKAGECONFIG[tests] = "--enable-tests,--disable-tests,cunit" |
| 33 | |
| 34 | EXTRA_OECONF = "\ |
| 35 | --with-epoll --enable-add-default-names \ |
| 36 | --without-tinydtls \ |
| 37 | ${@bb.utils.contains_any('PACKAGECONFIG', 'gnutls openssl mbedtls', '--enable-dtls', '--disable-dtls', d)} \ |
| 38 | " |
| 39 | |
| 40 | python () { |
| 41 | if d.getVar('PTEST_ENABLED') == "1": |
| 42 | d.setVar('DISABLE_STATIC', '') |
| 43 | } |
| 44 | |
| 45 | export SGML_CATALOG_FILES="file://${STAGING_ETCDIR_NATIVE}/xml/catalog" |
| 46 | |
| 47 | do_install_ptest () { |
| 48 | install -d ${D}${PTEST_PATH} |
| 49 | install -m 0755 ${WORKDIR}/run-ptest ${D}${PTEST_PATH}/run-ptest |
| 50 | install -m 0755 ${B}/tests/testdriver ${D}${PTEST_PATH}/testdriver |
| 51 | } |
| 52 | |
| 53 | PACKAGE_BEFORE_PN += "\ |
| 54 | ${PN}-bin \ |
| 55 | " |
| 56 | |
| 57 | FILES:${PN}-bin = "${bindir}" |
| 58 | FILES:${PN}-dev += "${datadir}/${BPN}/examples" |