| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 1 | SUMMARY = "OpenMAX IL plugins for GStreamer" |
| 2 | DESCRIPTION = "Wraps available OpenMAX IL components and makes them available as standard GStreamer elements." |
| 3 | HOMEPAGE = "http://gstreamer.freedesktop.org/" |
| 4 | SECTION = "multimedia" |
| 5 | |
| 6 | LICENSE = "LGPL-2.1-or-later" |
| 7 | LICENSE_FLAGS = "commercial" |
| 8 | LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \ |
| 9 | file://omx/gstomx.h;beginline=1;endline=21;md5=5c8e1fca32704488e76d2ba9ddfa935f" |
| 10 | |
| 11 | SRC_URI = "https://gstreamer.freedesktop.org/src/gst-omx/gst-omx-${PV}.tar.xz" |
| 12 | |
| Andrew Geissler | d583833 | 2022-05-27 11:33:10 -0500 | [diff] [blame] | 13 | SRC_URI[sha256sum] = "7efed7cc5b0acf9a669e38c5360a7892430a4e86c858daac6faa1ade2b151668" |
| Andrew Geissler | 9aee500 | 2022-03-30 16:27:02 +0000 | [diff] [blame] | 14 | |
| 15 | S = "${WORKDIR}/gst-omx-${PV}" |
| 16 | |
| 17 | DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad virtual/libomxil" |
| 18 | |
| 19 | inherit meson pkgconfig upstream-version-is-even |
| 20 | |
| 21 | GSTREAMER_1_0_OMX_TARGET ?= "bellagio" |
| 22 | GSTREAMER_1_0_OMX_CORE_NAME ?= "${libdir}/libomxil-bellagio.so.0" |
| 23 | |
| 24 | EXTRA_OEMESON += "-Dtarget=${GSTREAMER_1_0_OMX_TARGET}" |
| 25 | |
| 26 | python __anonymous () { |
| 27 | omx_target = d.getVar("GSTREAMER_1_0_OMX_TARGET") |
| 28 | if omx_target in ['generic', 'bellagio']: |
| 29 | # Bellagio headers are incomplete (they are missing the OMX_VERSION_MAJOR,# |
| 30 | # OMX_VERSION_MINOR, OMX_VERSION_REVISION, and OMX_VERSION_STEP macros); |
| 31 | # appending a directory path to gst-omx' internal OpenMAX IL headers fixes this |
| 32 | d.appendVar("CFLAGS", " -I${S}/omx/openmax") |
| 33 | elif omx_target == "rpi": |
| 34 | # Dedicated Raspberry Pi OpenMAX IL support makes this package machine specific |
| 35 | d.setVar("PACKAGE_ARCH", d.getVar("MACHINE_ARCH")) |
| 36 | } |
| 37 | |
| 38 | set_omx_core_name() { |
| 39 | sed -i -e "s;^core-name=.*;core-name=${GSTREAMER_1_0_OMX_CORE_NAME};" "${D}${sysconfdir}/xdg/gstomx.conf" |
| 40 | } |
| 41 | do_install[postfuncs] += " set_omx_core_name " |
| 42 | |
| 43 | FILES:${PN} += "${libdir}/gstreamer-1.0/*.so" |
| 44 | FILES:${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a" |
| 45 | |
| 46 | VIRTUAL-RUNTIME_libomxil ?= "libomxil" |
| 47 | RDEPENDS:${PN} = "${VIRTUAL-RUNTIME_libomxil}" |