| Brad Bishop | 316dfdd | 2018-06-25 12:45:53 -0400 | [diff] [blame] | 1 | SUMMARY = "tool for automating interactive applications according to a script" |
| 2 | DESCRIPTION = "Expect is a tool for automating interactive applications according to a script. \ |
| 3 | Following the script, Expect knows what can be expected from a program and what \ |
| 4 | the correct response should be. Expect is also useful for testing these same \ |
| 5 | applications. And by adding Tk, you can also wrap interactive applications in \ |
| 6 | X11 GUIs. An interpreted language provides branching and high-level control \ |
| 7 | structures to direct the dialogue. In addition, the user can take control and \ |
| 8 | interact directly when desired, afterward returning control to the script. \ |
| 9 | " |
| 10 | HOMEPAGE = "http://sourceforge.net/projects/expect/" |
| 11 | LICENSE = "PD" |
| 12 | SECTION = "devel" |
| 13 | |
| 14 | LIC_FILES_CHKSUM = "file://license.terms;md5=fbf2de7e9102505b1439db06fc36ce5c" |
| 15 | |
| 16 | DEPENDS += "tcl" |
| 17 | RDEPENDS_${PN} = "tcl" |
| 18 | |
| 19 | inherit autotools update-alternatives |
| 20 | |
| 21 | SRC_URI = "${SOURCEFORGE_MIRROR}/expect/Expect/${PV}/${BPN}${PV}.tar.gz \ |
| 22 | file://0001-configure.in.patch \ |
| 23 | file://0002-tcl.m4.patch \ |
| 24 | file://01-example-shebang.patch \ |
| 25 | file://0001-expect-install-scripts-without-using-the-fixline1-tc.patch \ |
| 26 | file://0001-Resolve-string-formatting-issues.patch \ |
| 27 | file://0001-expect-Fix-segfaults-if-Tcl-is-built-with-stubs-and-.patch \ |
| 28 | " |
| 29 | SRC_URI[md5sum] = "00fce8de158422f5ccd2666512329bd2" |
| 30 | SRC_URI[sha256sum] = "49a7da83b0bdd9f46d04a04deec19c7767bb9a323e40c4781f89caf760b92c34" |
| 31 | |
| 32 | UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/expect/files/Expect/" |
| 33 | UPSTREAM_CHECK_REGEX = "/Expect/(?P<pver>(\d+[\.\-_]*)+)/" |
| 34 | |
| 35 | S = "${WORKDIR}/${BPN}${PV}" |
| 36 | |
| 37 | do_install_append() { |
| 38 | install -d ${D}${libdir} |
| 39 | install -m 0755 ${D}${libdir}/expect${PV}/libexpect*.so ${D}${libdir}/ |
| 40 | install -m 0755 ${S}/fixline1 ${D}${libdir}/expect${PV}/ |
| 41 | install -m 0755 ${S}/example/* ${D}${libdir}/expect${PV}/ |
| 42 | rm ${D}${libdir}/expect${PV}/libexpect*.so |
| 43 | sed -e 's|$dir|${libdir}|' -i ${D}${libdir}/expect${PV}/pkgIndex.tcl |
| 44 | } |
| 45 | |
| 46 | # Apparently the public Tcl headers are only in /usr/include/tcl8.6 |
| 47 | # when building for the target. |
| 48 | TCL_INCLUDE_PATH = "" |
| 49 | TCL_INCLUDE_PATH_class-target = "--with-tclinclude=${STAGING_INCDIR}/tcl8.6" |
| 50 | |
| 51 | EXTRA_OECONF += "--with-tcl=${STAGING_LIBDIR} \ |
| 52 | --enable-shared \ |
| 53 | --enable-threads \ |
| 54 | --disable-rpath \ |
| 55 | ${TCL_INCLUDE_PATH} \ |
| 56 | " |
| 57 | EXTRA_OEMAKE_install = " 'SCRIPTS=' " |
| 58 | |
| 59 | ALTERNATIVE_${PN} = "mkpasswd" |
| 60 | ALTERNATIVE_LINK_NAME[mkpasswd] = "${bindir}/mkpasswd" |
| 61 | # Use lower priority than busybox's mkpasswd (created when built with CONFIG_CRYPTPW) |
| 62 | ALTERNATIVE_PRIORITY[mkpasswd] = "40" |
| 63 | |
| 64 | FILES_${PN}-dev = "${libdir_native}/expect${PV}/libexpect*.so \ |
| 65 | ${includedir}/expect.h \ |
| 66 | ${includedir}/expect_tcl.h \ |
| 67 | ${includedir}/expect_comm.h \ |
| 68 | ${includedir}/tcldbg.h \ |
| 69 | ${includedir}/*.h \ |
| 70 | " |
| 71 | |
| 72 | FILES_${PN} += "${libdir}/libexpect${PV}.so \ |
| 73 | ${libdir}/expect${PV}/* \ |
| 74 | " |
| 75 | |
| 76 | BBCLASSEXTEND = "native nativesdk" |