| SUMMARY = "Freetype font rendering library" |
| DESCRIPTION = "FreeType is a software font engine that is designed to be small, efficient, \ |
| highly customizable, and portable while capable of producing high-quality output (glyph \ |
| images). It can be used in graphics libraries, display servers, font conversion tools, text \ |
| image generation tools, and many other products as well." |
| HOMEPAGE = "http://www.freetype.org/" |
| BUGTRACKER = "https://savannah.nongnu.org/bugs/?group=freetype" |
| SECTION = "libs" |
| |
| LICENSE = "FreeType | GPLv2+" |
| LIC_FILES_CHKSUM = "file://docs/LICENSE.TXT;md5=4af6221506f202774ef74f64932878a1 \ |
| file://docs/FTL.TXT;md5=d479e83797f699fe873b38dadd0fcd4c \ |
| file://docs/GPLv2.TXT;md5=8ef380476f642c20ebf40fecb0add2ec" |
| |
| SRC_URI = "${SOURCEFORGE_MIRROR}/freetype/freetype-${PV}.tar.bz2 \ |
| file://use-right-libtool.patch" |
| |
| SRC_URI[md5sum] = "0037b25a8c090bc8a1218e867b32beb1" |
| SRC_URI[sha256sum] = "371e707aa522acf5b15ce93f11183c725b8ed1ee8546d7b3af549863045863a2" |
| |
| inherit autotools pkgconfig binconfig-disabled multilib_header |
| |
| # Adapt autotools to work with the minimal autoconf usage in freetype |
| AUTOTOOLS_SCRIPT_PATH = "${S}/builds/unix" |
| CONFIGURE_SCRIPT = "${S}/configure" |
| EXTRA_AUTORECONF += "--exclude=autoheader --exclude=automake" |
| |
| PACKAGECONFIG ??= "zlib" |
| |
| PACKAGECONFIG[bzip2] = "--with-bzip2,--without-bzip2,bzip2" |
| # harfbuzz results in a circular dependency so enabling is non-trivial |
| PACKAGECONFIG[harfbuzz] = "--with-harfbuzz,--without-harfbuzz,harfbuzz" |
| PACKAGECONFIG[pixmap] = "--with-png,--without-png,libpng" |
| PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib" |
| |
| EXTRA_OECONF = "CC_BUILD='${BUILD_CC}'" |
| |
| TARGET_CPPFLAGS += "-D_FILE_OFFSET_BITS=64" |
| |
| do_install_append() { |
| oe_multilib_header freetype2/freetype/config/ftconfig.h |
| } |
| |
| BINCONFIG = "${bindir}/freetype-config" |
| |
| BBCLASSEXTEND = "native" |