| Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 1 | SUMMARY = "Apache Thrift" |
| 2 | DESCRIPTION = "A software framework, for scalable cross-language services development" |
| 3 | HOMEPAGE = "https://thrift.apache.org/" |
| 4 | |
| 5 | LICENSE = "Apache-2.0" |
| 6 | LIC_FILES_CHKSUM = "file://LICENSE;md5=c40a383cb3f747e0c7abbf1482f194f0 \ |
| 7 | file://NOTICE;md5=2659b43daca219f99a2f2626ea128f73" |
| 8 | |
| 9 | DEPENDS = "thrift-native boost flex-native bison-native openssl zlib" |
| 10 | |
| 11 | SRC_URI = "https://www-eu.apache.org/dist/thrift//${PV}/${BPN}-${PV}.tar.gz \ |
| 12 | file://0001-DefineInstallationPaths.cmake-Define-libdir-in-terms.patch \ |
| 13 | " |
| Patrick Williams | 03907ee | 2022-05-01 06:28:52 -0500 | [diff] [blame^] | 14 | SRC_URI[sha256sum] = "f460b5c1ca30d8918ff95ea3eb6291b3951cf518553566088f3f2be8981f6209" |
| Patrick Williams | 213cb26 | 2021-08-07 19:21:33 -0500 | [diff] [blame] | 15 | |
| 16 | BBCLASSEXTEND = "native nativesdk" |
| 17 | |
| 18 | inherit pkgconfig cmake python3native |
| 19 | |
| 20 | export STAGING_INCDIR |
| 21 | export STAGING_LIBDIR |
| 22 | export BUILD_SYS |
| 23 | export HOST_SYS |
| 24 | |
| 25 | EXTRA_OECMAKE = " \ |
| 26 | -DBUILD_LIBRARIES=ON \ |
| 27 | -DBUILD_SHARED_LIBS=ON \ |
| 28 | -DBUILD_COMPILER=ON \ |
| 29 | -DBUILD_TESTING=OFF \ |
| 30 | -DBUILD_TUTORIALS=OFF \ |
| 31 | -DWITH_AS3=OFF \ |
| 32 | -DWITH_CPP=ON \ |
| 33 | -DWITH_JAVA=OFF \ |
| 34 | -DWITH_OPENSSL=ON \ |
| 35 | -DWITH_QT5=OFF \ |
| 36 | -DWITH_ZLIB=ON \ |
| 37 | " |
| 38 | |
| 39 | PACKAGECONFIG ??= "glib libevent" |
| 40 | PACKAGECONFIG[glib] = "-DWITH_C_GLIB=ON,-DWITH_C_GLIB=OFF,glib-2.0" |
| 41 | PACKAGECONFIG[libevent] = "-DWITH_LIBEVENT=ON,-DWITH_LIBEVENT=OFF,libevent" |
| 42 | PACKAGECONFIG[javascript] = "-DWITH_JAVASCRIPT=ON,-DWITH_JAVASCRIPT=OFF,nodejs" |
| 43 | PACKAGECONFIG[nodejs] = "-DWITH_NODEJS=ON,-DWITH_NODEJS=OFF,nodejs" |
| 44 | PACKAGECONFIG[python] = "-DWITH_PYTHON=ON,-DWITH_PYTHON=OFF,python" |
| 45 | |
| 46 | do_install:append () { |
| 47 | ln -sf thrift ${D}/${bindir}/thrift-compiler |
| 48 | } |
| 49 | |
| 50 | LEAD_SONAME = "libthrift.so.${PV}" |
| 51 | |
| 52 | # thrift packages |
| 53 | PACKAGE_BEFORE_PN = "${PN}-compiler lib${BPN} lib${BPN}z lib${BPN}nb lib${BPN}-c-glib" |
| 54 | FILES:lib${BPN} = "${libdir}/libthrift.so.*" |
| 55 | FILES:lib${BPN}z = "${libdir}/libthriftz.so.*" |
| 56 | FILES:lib${BPN}nb = "${libdir}/libthriftnb.so.*" |
| 57 | FILES:lib${BPN}-c-glib = "${libdir}/libthrift_c_glib.so.*" |
| 58 | FILES:${PN}-compiler = "${bindir}/*" |
| 59 | |
| 60 | # The thrift packages just pulls in some default dependencies but is otherwise empty |
| 61 | RRECOMMENDS:${PN} = "${PN}-compiler lib${BPN}" |
| 62 | ALLOW_EMPTY:${PN} = "1" |
| 63 | RRECOMMENDS:${PN}:class-native = "" |
| 64 | RRECOMMENDS:${PN}:class-nativesdk = "" |