| Patrick Williams | d8c66bc | 2016-06-20 12:57:21 -0500 | [diff] [blame] | 1 | SUMMARY = "Lightweight high-performance web server" |
| 2 | HOMEPAGE = "http://www.lighttpd.net/" |
| 3 | BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues" |
| 4 | |
| 5 | LICENSE = "BSD" |
| 6 | LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579" |
| 7 | |
| 8 | SECTION = "net" |
| 9 | DEPENDS = "zlib libpcre" |
| 10 | RDEPENDS_${PN} += " \ |
| 11 | lighttpd-module-access \ |
| 12 | lighttpd-module-accesslog \ |
| 13 | lighttpd-module-indexfile \ |
| 14 | lighttpd-module-dirlisting \ |
| 15 | lighttpd-module-staticfile \ |
| 16 | " |
| 17 | |
| 18 | SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.xz \ |
| 19 | file://index.html.lighttpd \ |
| 20 | file://lighttpd.conf \ |
| 21 | file://lighttpd \ |
| 22 | file://lighttpd.service \ |
| 23 | file://pkgconfig.patch \ |
| 24 | " |
| 25 | |
| 26 | SRC_URI[md5sum] = "63c7563be1c7a7a9819a51f07f1af8b2" |
| 27 | SRC_URI[sha256sum] = "7eb9a1853c3d6dd5851682b0733a729ba4158d6bdff80974d5ef5f1f6887365b" |
| 28 | |
| 29 | PACKAGECONFIG ??= "openssl" |
| 30 | PACKAGECONFIG[openssl] = "--with-openssl, --without-openssl, openssl" |
| 31 | |
| 32 | EXTRA_OECONF = " \ |
| 33 | --without-bzip2 \ |
| 34 | --without-ldap \ |
| 35 | --without-lua \ |
| 36 | --without-memcache \ |
| 37 | --with-pcre \ |
| 38 | --without-webdav-props \ |
| 39 | --without-webdav-locks \ |
| 40 | --disable-static \ |
| 41 | " |
| 42 | |
| 43 | inherit autotools pkgconfig update-rc.d gettext systemd |
| 44 | |
| 45 | INITSCRIPT_NAME = "lighttpd" |
| 46 | INITSCRIPT_PARAMS = "defaults 70" |
| 47 | |
| 48 | SYSTEMD_SERVICE_${PN} = "lighttpd.service" |
| 49 | |
| 50 | do_install_append() { |
| 51 | install -d ${D}${sysconfdir}/init.d ${D}${sysconfdir}/lighttpd.d ${D}/www/pages/dav |
| 52 | install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d |
| 53 | install -m 0644 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir} |
| 54 | install -m 0644 ${WORKDIR}/index.html.lighttpd ${D}/www/pages/index.html |
| 55 | |
| 56 | install -d ${D}${systemd_unitdir}/system |
| 57 | install -m 0644 ${WORKDIR}/lighttpd.service ${D}${systemd_unitdir}/system |
| 58 | sed -i -e 's,@SBINDIR@,${sbindir},g' \ |
| 59 | -e 's,@SYSCONFDIR@,${sysconfdir},g' \ |
| 60 | -e 's,@BASE_BINDIR@,${base_bindir},g' \ |
| 61 | ${D}${systemd_unitdir}/system/lighttpd.service |
| 62 | #For FHS compliance, create symbolic links to /var/log and /var/tmp for logs and temporary data |
| 63 | ln -sf ${localstatedir}/log ${D}/www/logs |
| 64 | ln -sf ${localstatedir}/tmp ${D}/www/var |
| 65 | } |
| 66 | |
| 67 | FILES_${PN} += "${sysconfdir} /www" |
| 68 | |
| 69 | CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf" |
| 70 | |
| 71 | PACKAGES_DYNAMIC += "^lighttpd-module-.*" |
| 72 | |
| 73 | python populate_packages_prepend () { |
| 74 | lighttpd_libdir = d.expand('${libdir}') |
| 75 | do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='') |
| 76 | } |